Nur lesen Benutzerdefinierte Eigenschaften

Question

Ich habe benutzerdefinierte Eigenschaften (Metadaten) für MS Word von VBA hinzugefügt, aber wie mache ich es nur lesen, so dass es nicht leicht geändert werden kann?

Answer 1

Sie können nicht.

Je nachdem, welche Art von Szenario Sie vermeiden möchten, können Sie möglicherweise die Eigenschaften durch Verschlüsselung der Inhalte "obfuscate" irgendwie. Das würde es einem Benutzer schwerer machen, herauszufinden, wie man sie zu etwas Nützlichem ändert - aber es würde den Benutzer nicht davon abhalten, es zu "brechen".

Answer 2

Statt Dokumenteigenschaften verwenden verwenden Dokumentvariablen (http://msdn.microsoft.com/en-us/library/bb212231.aspx). Sie können nur über Code darauf zugreifen. Es gibt keine Benutzeroberfläche für sie.

Hier einige alte VB6/VBA-Funktionen die ich für sie verwendet:

Public Sub SetVariable(oDocument As Word.Document, sName As String, sValue As String) 

     Dim oVariable As Word.Variable 

     Set oVariable = LocateVariable(oDocument, sName) 

     If Not oVariable Is Nothing Then 

      oVariable.Value = sValue 

     Else 

      oDocument.Variables.Add sName, sValue 

     End If 

End Sub 

Public Function GetVariable(oDocument As Word.Document, sName As String) As String 

     Dim oVariable As Word.Variable 

     Set oVariable = LocateVariable(oDocument, sName) 

     If Not oVariable Is Nothing Then 

      GetVariable = oVariable.Value 

     Else 

      GetVariable = "" 

     End If 

End Function 

Public Function LocateVariable(oDocument As Word.Document, sName As String) As Word.Variable 

     Dim oVariable As Word.Variable 

     For Each oVariable In oDocument.Variables 

      If StrComp(oVariable.Name, sName, vbTextCompare) = 0 Then 

       Set LocateVariable = oVariable 

       Exit Function 

      End If 

     Next 

     Set LocateVariable = Nothing 

End Function