Reagiere im Programm auf den Signalwechsel

Question

Ich möchte im Programm (VCL) auf den Signalwechsel einer Booleschen Variable reagieren (z. B. die verschiedenen Funktionen aufrufen - Messung starten/stoppen). Wie kann ich es realisieren? Gibt es einen anderen Weg ohne Timer?

Ich benutze Delphi 7 und ich arbeite mit Delphi für nur kurze Zeit.

Answer 1

Sie müssen eine Setter-Methode für die Eigenschaft verwenden und innerhalb dieser Setter überprüfen, ob der neue Wert vom aktuellen Wert abweicht.

Wenn ja, dann wird der Wert eingestellt und Feuer ein Ereignis (hier die OnCanStartChanged)

uses 
    Classes; 

type 
    TFoo = class 
    private 
    FCanStart   : Boolean; 
    FOnCanStartChanged: TNotifyEvent; 
    procedure SetCanStart(const Value: Boolean); 
    procedure SetOnCanStartChanged(const Value: TNotifyEvent); 
    protected 
    procedure DoCanStartChanged(); virtual; 
    public 
    property CanStart   : Boolean read FCanStart write SetCanStart; 
    property OnCanStartChanged: TNotifyEvent read FOnCanStartChanged write SetOnCanStartChanged; 
    end; 

    { TFoo } 

procedure TFoo.DoCanStartChanged; 
begin 
    if Assigned(FOnCanStartChanged) 
    then 
    FOnCanStartChanged(Self); 
end; 

procedure TFoo.SetCanStart(const Value: Boolean); 
begin 
    if FCanStart <> Value 
    then 
    begin 
     FCanStart := Value; 
     DoCanStartChanged(); 
    end; 
end; 

procedure TFoo.SetOnCanStartChanged(const Value: TNotifyEvent); 
begin 
    FOnCanStartChanged := Value; 
end;