VBA-Laufzeitfehler 424 Benötigtes Objekt

Question

Dies ist das erste Mal, dass ich VBA verwende und versuche herauszufinden, was ich hier falsch mache. Weiß jemand, warum ich diesen Fehler bekomme?

Sub CountHighSales() 
    Dim i As Integer 
    Dim j As Integer 
    Dim nHigh As Integer 
    Dim cutoff As Currency 

    cutoff = InputBox("What sales value do you want to check for?") 
    For j = 1 To 6 
     nHigh = 0 
     For i = 1 To 36 
      If wsData.Range("Sales").Cells(i, j) >= cutoff Then _ 
       nHigh = nHigh + 1 
     Next i 

     MsgBox ("For region " & j & ", sales were above " & Format(cutoff, "$0,000") & " on " & nHigh & " of the 36 months.") 

    Next j 
End Sub 

Answer 1

versuchen, diese (kommentierte) Code:

Option Explicit 

Sub CountHighSales() 
    Dim nHigh As Integer 
    Dim cutoff As Currency 
    Dim wsData As Worksheet 
    Dim j As Long 

    Set wsData = Worksheets("MyData") '<--| set your data worksheet (change "MyData" to your actual worksheet with data name) 
    cutoff = Application.InputBox("What sales value do you want to check for?", "cutoff value", , , , , , 1) '<--| use 'Application.InputBox()' method with 'Type' parameter set to 1 to force a "numeric" input 
    With wsData.Range("Sales") '<--| reference the named range of given worksheet 
     For j = 1 To .columns.Count '<--| loop through referenced range columns 
      nHigh = WorksheetFunction.CountIf(.columns(j), ">=" & cutoff) '<--| count current column cells above cutoff value 
      MsgBox ("For region " & j & ", sales were above " & Format(cutoff, "$0,000") & " on " & nHigh & " of the 36 months.") 
     Next j 
    End With 
End Sub