Wie kann ich einen einzigen Teil eines Hash in Perl bekommen?

Question

Gibt es eine Möglichkeit, einen Sub-Hash zu erhalten? Muss ich ein Hash-Slice verwenden?

Zum Beispiel:

%hash = (a => 1, b => 2, c => 3); 

Ich mag nur

%hash = (a => 1, b => 2); 

Answer 1

Hash slices geben Sie die Werte zurück, die mit einer Liste von Schlüsseln verknüpft sind. Um ein Hash-Slice Sie das Siegel zu @ ändern und stellt eine Liste von Schlüsseln (in diesem Fall "a" und "b"):

my @items = @hash{"a", "b"}; 

Oft können Sie ein Zitat Wort Operator verwenden, um die Liste zu produzieren:

my @items = @hash{qw/a b/}; 

Sie können auch auf einen Hash Scheibe, weisen also, wenn Sie einen neuen Hash möchten, die eine Teilmenge einer anderen Hash enthält können Sie

my %new_hash; 
@new_hash{qw/a b/} = @hash{qw/a b/}; 

Viele Menschen eine 012 sagen verwendenstatt Hash-Scheiben:

my %new_hash = map { $_ => $hash{$_} } qw/a b/; 

Beginnend mit Perl 5.20.0, können Sie die Schlüssel und die Werte in einem Schritt, wenn man das% Sigill anstelle des @ Sigill verwenden:

my %new_hash = %hash{qw/a b/}; 

Answer 2

Ein Hash ein ungeordneter Behälter ist, aber der Begriff Scheibe nur dann wirklich sinnvoll im Sinne eines geordneten Behälters. Vielleicht schauen Sie sich ein Array an. Andernfalls müssen Sie möglicherweise nur alle Elemente entfernen, die nicht Ihren 'Sub-Hash' erzeugen sollen.

Answer 3

Sie würden vermutlich eine Liste der Schlüssel montieren wollen Sie wollen:

my @keys = qw(a b); 

Und dann eine Schleife verwenden, um den Hash zu machen:

my %hash_slice; 
for(@keys) { 
    $hash_slice{$_} = %hash{$_}; 
} 

Oder:

my %hash_slice = map { $_ => $hash{$_} } @keys; 

(Meine Vorliebe ist die zweite, aber die, die Sie mögen, ist am besten.)

Answer 4

Zu viel funktionale Programmierung führt mich zuerst an zip denken.

Mit List::MoreUtils installiert,

use List::MoreUtils qw(zip); 

%hash = qw(a 1 b 2 c 3); 
@keys = qw(a b); 
@values = @hash{@keys}; 
%hash = zip @keys, @values; 

Leider ist der Prototyp der Liste :: MoreUtils der zip hemmt

zip @keys, @hash{@keys}; 

Wenn Sie wirklich die Zwischenvariable vermeiden wollen, könnten Sie

zip @keys, @{[@hash{@keys}]}; 

Oder schreiben Sie einfach Ihre eigene zip ohne den problematischen Prototyp. (Dies benötigt List :: MoreUtils überhaupt nicht.)

sub zip { 
    my $max = -1; 
    $max < $#$_and $max = $#$_ for @_; 
    map { my $ix = $_; map $_->[$ix], @_; } 0..$max; 
} 

%hash = zip \@keys, [@hash{@keys}]; 

---

Wenn Sie an Ort und Stelle zu mutieren,

%hash = qw(a 1 b 2 c 3); 
%keep = map +($_ => 1), qw(a b); 
$keep{$a} or delete $hash{$a} while ($a, $b) = each %hash; 

vermeidet das zusätzliche Kopieren gehen, dass die map und zip Lösungen entstehen. (. Ja, Mutieren der Hash, während Sie über es sind Iterieren ist sicher ... solange die Mutation nur die zuletzt iteriert Paar zu löschen)

Answer 5

FWIW, ich benutze Moose :: Autobox hier:

my $hash = { a => 1, b => 2, c => 3, d => 4 }; 
$hash->hslice([qw/a b/]) # { a => 1, b => 2 }; 

Im echten Leben, ich benutze dies um "Benutzername" und "Passwort" aus einem Formular zu extrahieren, und übergeben diese an Catalyst $c->authenticate (die in meinem Fall erwartet, eine Hashref mit dem Benutzernamen und Passwort, aber sonst nichts).

Answer 6

Noch eine andere Art und Weise:

my @keys = qw(a b); 
my %hash = (a => 1, b => 2, c => 3); 
my %hash_copy; 
@hash_copy{@keys} = @hash{@keys}; 

Answer 7

Neu in Perl 5.20 ist Hash-Scheiben Schlüssel sowie Werte durch die Verwendung% wie in der letzten Zeile hier Rückkehr:

my %population = ('Norway',5000000,'Sweden',9600000,'Denmark',5500000); 
my @slice_values = @population{'Norway','Sweden'}; # all perls can do this 
my %slice_hash = %population{'Norway','Sweden'}; # perl >= 5.20 can do this!