Nicht in der Lage, Bat-Datei Formular VBScript zu starten, wenn Pfad ein Leerzeichen enthält

Question

Ich habe versucht, myFileToRun.bat-Datei von einem Pfad zum Beispiel zu starten.

D:\My Folder\batchfiles\myFileToRun.bat 

Unten ist das VBScript, durch das ich versuche, es auszuführen.

Dim WshShell, strCurrentDirectory 
Set WshShell = CreateObject("WScript.Shell") 
strCurrentDirectory = WshShell.CurrentDirectory 
WshShell.Run strCurrentDirectory & "\myFileToRun.bat" , 0 
Set WshShell = Nothing 

Ich bin nicht in der Lage, es zu laufen, als VBS Fehler thowing sayin „System die angegebene Datei nicht finden kann:“ Ich habe in anderen ähnlichen Stellen in Stackoverflow und anderen Foren erwähnten verschiedene Methoden ausprobiert. Die meisten von ihnen sagen, doppelte Anführungszeichen hinzuzufügen.

Anmerkung: Ich habe doppelte Anführungszeichen versucht, das Hinzufügen, Doppel doppelte Anführungszeichen zum Beispiel

1.WshShell.Run """strCurrentDirectory & "\myFileToRun.bat" "", 0 
2.WshShell.Run """"strCurrentDirectory & "\myFileToRun.bat"""", 0 
3.WshShell.Run """"strCurrentDirectory & \myFileToRun.bat"""", 0 

Keiner von ihnen arbeitete, wie ich glaube, ich Zitate an falschen Stellen gebe. Die Variable strCurrentDirectory ändert sich in "strCurrentDirectory" anstelle von "D: \ My Folder \ Batchfiles" und mein endgültiger Pfad wäre "strCurrentDirectory" "\ myFileToRun.bat", was falsch ist. Ich brauche den Pfad zu "D: \ Mein Ordner \ Batchfiles \ myFileToRun.bat" und die Datei zu laufen.

Ich habe das Konzept dieser Zitate nicht wirklich verstanden. Also kannst du mir bitte dieses Konzept erklären und mir helfen, diesen Fehler zu beheben.

Edit: Ich habe die Lösung. Da ich mich auf das aktuelle Verzeichnis beziehen musste, habe ich das Skript einfach gemacht.

Dim WshShell 
Set WshShell = CreateObject("WScript.Shell") 
WshShell.Run "myFileToRun.bat", 0 
Set WshShell = Nothing 

Vielen Dank für Ihre Antworten. Es war hilfreich.

Answer 1

versuchen wie folgt aus:

Dim WshShell, strCurrentDirectory 
Set WshShell = CreateObject("WScript.Shell") 
strCurrentDirectory = WshShell.CurrentDirectory 
WshShell.Run """" & strCurrentDirectory & "\di r\myFileToRun.bat" & """" , 0 
Set WshShell = Nothing 

Answer 2

Diese Funktion doppelte Anführungszeichen in Variablen hinzufügen können:

Function DblQuote(Str) 
    DblQuote = Chr(34) & Str & Chr(34) 
End Function 

So wird der Code zum Lesen einfach:

Dim WshShell, strCurrentDirectory 
Set WshShell = CreateObject("WScript.Shell") 
strCurrentDirectory = WshShell.CurrentDirectory 
wscript.echo DblQuote(strCurrentDirectory & "\My Folder\myFileToRun.bat") 
WshShell.Run DblQuote(strCurrentDirectory & "\My Folder\myFileToRun.bat"),0 
Set WshShell = Nothing 
'******************************************************************** 
Function DblQuote(Str) 
    DblQuote = Chr(34) & Str & Chr(34) 
End Function 
'******************************************************************** 

Answer 3

Sie müssen nur die Anführungszeichen in der Zeichenfolge korrekt umgehen, die Regel ist immer dann, wenn Sie ein Anführungszeichen in einer Zeichenfolge anzeigen möchten uble es.

Also, dieser Befehl

WshShell.Run strCurrentDirectory & "\myFileToRun.bat" , 0 

Im Moment wird als übergeben werden;

D:\My Folder\batchfiles\myFileToRun.bat 

Wie bei den meisten Windows-Programme Pfade mit Leerzeichen mit Anführungszeichen umgeben werden müssen, wenn Sie den vollständigen Pfad, um sicherzustellen, übergeben wird anerkannt, im Moment Run() sieht

D:\My 

und den Rest als Argument an das Programm My übergeben.Da das System nicht in der Lage sein, das My Programm zu finden, führt dazu, dass das

System die Datei

angegebene Fehler nicht finden kann.

dies beheben wir eine Zeichenfolge in Anführungszeichen (Verdoppelung der Angebote für jedes wörtliche Zitat wir aufnehmen wollen)

WshShell.Run """" & strCurrentDirectory & "\myFileToRun.bat""", 0 

, die als übergeben müssen weitergegeben werden;

"D:\My Folder\batchfiles\myFileToRun.bat" 

Hinweis: Wenn mit Variablen verketten müssen wir noch öffnen und die Zeichenfolge richtig zu schließen. Für eine Situation wie oben verketten wir die Zeichenkette """" mit einer Variablen, die einfach "" ist, aber mit einem öffnenden und schließenden Zitat, um die literale Zeichenkette zu bezeichnen.

Auch müssen Variablen korrekt an die Zeichenfolge verkettet werden oder werden Sie seltsame Ergebnisse erhalten, zum Beispiel Ihre erste Versuch, die Zeichenfolge

WshShell.Run """strCurrentDirectory & "\myFileToRun.bat" "", 0 

würde dazu führen, zu entkommen;

Erwartete Ende der Anweisung

weil es kein richtig terminierten String ist.