XSLT Stammnamespace entfernen und fügen Sie Namespace zu einem anderen Element

Question

ich einen Eingang xml haben -

<?xml version="1.0" encoding="UTF-8" standalone="yes"?> 
<Root xmlns="http://www.somenamespace"> 
    <Child1> 
     <A>a</A> 
     <B>b</B> 
    </Child1> 
    <Child2> 
     <C>c</C> 
     <D>d</D> 
    </Child2> 
</Root> 

ich meine Ausgabe xml wollen nach der Transformation den Namespace von der Wurzel zu entfernen und sie zu Element Child1 hinzufügen, anstatt wie this-

<?xml version="1.0" encoding="UTF-8" standalone="yes"?> 
<NewRoot> 
    <NewChild1 xmlns="http://www.somenamespace"> 
     <A>a</A> 
     <B>b</B> 
    </NewChild1> 
    <NewChild2> 
     <C>c</C> 
     <D>d</D> 
    </NewChild2> 
</NewRoot> 

Mein xslt sieht wie-

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns="http://www.somenamespace" 
      xmlns:test="http://www.somenamespace" 
      exclude-result-prefixes="test"> 
    <xsl:output method="xml" indent="yes" version="1.0" encoding="UTF-8" standalone="yes"/> 
    <xsl:template match="/"> 
    <NewRoot> 
     <xsl:apply-templates select="test:Root/test:Child1"/> 
     <xsl:apply-templates select="test:Root/test:Child2"/> 
    </NewRoot> 
    </xsl:template> 
    <xsl:template match="test:Root/test:Child1"> 
     <NewChild1> <xsl:value-of select="current()"/> </NewChild1> 
    </xsl:template> 
    <xsl:template match="test:Root/test:Child2"> 
     <NewChild2> <xsl:value-of select="current()"/> </NewChild2> 
    </xsl:template> 
</xsl:stylesheet> 

Derzeit wird diese den Namespace an die NewRoot fügt Element.

Answer 1

I würde vorschlagen, tun Sie es so:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:ns="http://www.somenamespace" 
exclude-result-prefixes="ns"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/"> 
    <NewRoot> 
     <xsl:apply-templates/> 
    </NewRoot> 
</xsl:template> 

<xsl:template match="ns:Child1"> 
    <NewChild1 xmlns="http://www.somenamespace"> 
     <xsl:copy-of select="*"/> 
    </NewChild1> 
</xsl:template> 

<xsl:template match="ns:Child2"> 
    <NewChild2> 
     <xsl:apply-templates mode="no-namespace"/> 
    </NewChild2> 
</xsl:template> 

<xsl:template match="*" mode="no-namespace"> 
    <xsl:element name="{local-name()}"> 
     <xsl:apply-templates/> 
    </xsl:element> 
</xsl:template> 

</xsl:stylesheet> 

Answer 2

Sie können es wie folgt ändern:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:test="http://www.somenamespace" 
      exclude-result-prefixes="test"> 
    <xsl:output method="xml" indent="yes" version="1.0" encoding="UTF-8" standalone="yes"/> 
    <xsl:template match="/"> 
    <NewRoot> 
     <xsl:apply-templates select="test:Root/test:Child1"/> 
     <xsl:apply-templates select="test:Root/test:Child2"/> 
    </NewRoot> 
    </xsl:template> 
    <xsl:template match="test:Root/test:Child1"> 
     <test:NewChild1> <xsl:value-of select="current()"/> </test:NewChild1> 
    </xsl:template> 
    <xsl:template match="test:Root/test:Child2"> 
     <NewChild2> <xsl:value-of select="current()"/> </NewChild2> 
    </xsl:template> 
</xsl:stylesheet> 

D.h. Deklarieren Sie keinen Standardnamespace (xmlns="..."), sondern setzen Sie NewChild1 explizit in den Namespace http://www.somenamespace.

Dies tut, was Sie gefragt haben, nämlich ändert Ihr Stylesheet, um "den Namespace von root zu entfernen und es Element Child1 hinzuzufügen"; aber es erzeugt nicht Ihre Beispielausgabe in allen Details (z. B. sind die <A> und <B> Elemente immer noch nicht erhalten, da Sie nicht um Hilfe gebeten haben). Anstatt Ihr Stylesheet vollständig neu zu schreiben, um Aspekte der Beispielausgabe zu reproduzieren, auf die Sie sich nicht konzentrieren sollten, überlasse ich es Ihnen und gebe Ihnen Feedback zu dem, wofür Sie speziell Hilfe brauchten.

In all dies wird es Zeit sparen und die Kommunikation einfacher machen, wenn Sie sicherstellen, dass Sie den Unterschied zwischen Namespace Erklärungen verstehen, Namespace Präfixe, und welche Namespace ein Element ist in.