Versucht, Access-Makro von

Question

auszuführen Ich versuche, ein Access Macro von Excel auszuführen. Ich habe einen Verweis auf Microsoft Office 14.0 Access-Datenbank-Engine-Objektbibliothek festgelegt. Jetzt versuche ich ein kleines Skript wie dieses zu starten.

Sub RunAccessMacro() 
    Dim strDatabasePath As String 
    Dim PathToDB As String 
    Dim db As DAO.Database 
    Dim rs As DAO.Recordset 

    PathOfDatabase = ThisWorkbook.Worksheets("Updates").Range("PathToAccess") 

    Set db = DAO.DBEngine.OpenDatabase(PathOfDatabase) 
    Set qry = db.Execute("Macro_Run_Key") 

    qry.Close 
    db.Close 

    MsgBox "Done! All processes complete!!" 

End Sub 

Das Problem ist, führen die db.Execute nicht das Makro. Ich sehe nicht einmal etwas wie RunMacro oder wie es heißt.

Es muss ein Weg, dies zu tun, richtig.

Answer 1

Die Datenbank-Engine nur Datenbank-Dinge (alles mit Tabellen und Abfragen). Wenn Sie mehr als das wollen, müssen Sie die Access-Anwendung durch VBA verwenden müssen:

Sub RunAccessMacro() 
    Dim strDatabasePath As String 
    Dim PathToDB As String 
    Dim accApp As Access.Application 
    Set accApp = New Access.Application 



    PathOfDatabase = ThisWorkbook.Worksheets("Updates").Range("PathToAccess") 
    accApp.OpenCurrentDatabase PathOfDatabase 
    accApp.DoCmd.RunMacro "Macro_Run_Key" 
    accApp.Quit 
    Set accApp = Nothing 


    MsgBox "Done! All processes complete!!" 

End Sub 

Außerdem müssen Sie einen Verweis auf die Microsoft Access-Objektbibliothek hinzufügen, oder können Sie diesen Code anpassen verwenden spät Bindungen.

Answer 2

einen Verweis auf die Access-Objektbibliothek Einstellung ist nutzlos , wenn Sie es tatsächlich :) Ernsthaft verwenden, geschrieben den obigen Code verwendet DAO, die als Aufruf Access direkt über das Objekt Libary ein anderes Tier ist. DAO ist streng genommen eine Datenbank-Engine (wie ADO) und kennt keine Makros und Module, wie sie in Office Apps definiert sind.

Hier ist der Code zu verwenden, wenn frühe Bindung mit:

Sub RunAccessMacro() 

    Dim PathOfDatabase As String 
    PathOfDatabase = ThisWorkbook.Worksheets("Updates").Range("PathToAccess") 

    Dim accApp As Access.Application 
    Set accApp = New Access.Application 

    With accApp 

     .OpenCurrentDatabase PathOfDatabase 
     .DoCmd.RunMacro "Macro_Run_Key" 
     .Quit 

    End With 

    MsgBox "Done! All processes complete!!" 

End Sub 

Answer 3

Wenn das Makro ein Access-Makro ist, können Sie das Makro mit einem einzigen Befehl tatsächlich auslösen können, anstatt um die Häuser zu gehen. Die/X-Befehlszeilenschalter wird helfen - diesen Link zu überprüfen: How can I schedule a Macro to run automatically in Access 2007