Woher kommt die Dezimalstelle in dieser Berechnung?

Question

Ich habe eine Funktion, die eine BOL-Nummer berechnet und nur die ersten 10 Ziffern nimmt.

Hier ist der Code.

Public Function GENERATEBOLNUMBER(iYearSuffix As Integer, _ 
           sFromZipcode As String, _ 
           sToZipCode As String, _ 
           iWeight As Integer, _ 
           iShowID As Integer) As String 

    Application.ScreenUpdating = False 

    GENERATEBOLNUMBER = VBA.Left(7 & _ 
    WorksheetFunction.RoundUp(VBA.Right(sFromZipcode, 5) _ 
    * VBA.Right(sToZipCode, 5) * iWeight * (iShowID + 1234), 0), 10) 

    Application.ScreenUpdating = True 
End Function 

Und hier sind die Werte, die ich es übergeben. 7 für den iYearSuffix, 78224 für sFromZipcode und 78224 für sToZipCode, 410 als iWeight und 1 als iShowID. All dies berechnet sich zu 3098352701017600, so dass die endgültige Zeichenfolge 7309835270 sein sollte, die die 7 als erste Ziffer und die folgenden 9 Ziffern enthält.

Woher kommt die Dezimalzahl? Die Antwort lautet: 73.0983527.

Answer 1

Sie mischen String-Handling, numerische Manipulation, implizite Umwandlungen zwischen Strings und Zahlen, VBA, WorksheetFunction und gigantische Zahlen. Was könnte möglicherweise falsch laufen?

Wenn Sie eine UDF in VBA schreiben, schreiben Sie sie in VBA. Der einzige Datentyp groß genug, um Ihr Ergebnis zu speichern, wird ein Decimal sein, so dass Sie es als Variant erklären müssen und werfen explizit die Berechnung sie zu zwingen, zu zwingen:

Public Function GENERATEBOLNUMBER(yearSuffix As Integer, fromZip As String, _ 
            toZip As String, weight As Integer, _ 
            showId As Integer) As String 
    Dim result As Variant 
    'Calculate intermediary result. 
    result = CDec(Right$(fromZip, 5)) * CDec(Right$(toZip, 5)) * weight * (showId + 1234) 
    'Shift the decimal place 7 places to the left: 
    result = result/10^7 
    'Skip the RoundUp call - it wasn't doing anything because your result was an integer. 
    'Strip the non-integer portion: 
    result = Fix(result) 
    'Cast to a string an concatenate the "7" onto the start: 
    GENERATEBOLNUMBER = "7" & CStr(result) 
End Function