Wie Sie ALT + F4 eines WinForm verhindern, aber alle anderen Formen des Schließens eines WinForm zulassen?

Question

ich um die interwebs und verschiedene Teile dieser Ressource gesucht haben, wo diese Frage gestellt wurde und bemerkte ich die folgenden Bit-Code bekam:

Protected Overrides ReadOnly Property CreateParams() As CreateParams 
    Get 
     Dim cp As CreateParams = MyBase.CreateParams 
     Const CS_NOCLOSE As Integer = &H200 
     cp.ClassStyle = cp.ClassStyle Or CS_NOCLOSE 
     Return cp 
    End Get 
End Property 

Welche wie vorgesehen funktioniert, tut dies deaktivieren ALT + F4 entfernt, benutzt. Doch als unbeabsichtigte Nebenwirkung dieses Code: das Fenster über das Control Box zu schließen ist deaktiviert:

Gibt es eine Version dieses Codes dass disables ALT+F4 aber immer noch für das Schließen des Fensters erlaubt über seine Kontrollbox oder andere UI-Optionen (wie zum Beispiel einer Schaltfläche zum Schließen und Schließen Option in einem Menü.)

ich kenne jemand sagt die e.CloseReason of the form jedoch UserClosing ist der einzige Grund, der ähnelt zu prüfen, was würde ich mag an tun Sie jedoch ..., dass die Benutzerschnittstelle immer noch deaktiviert ist. Es sei denn, es gibt einen Code, den ich vergessen habe.

Answer 1

Antwort auf Ihren Kommentar, KeyDown aus einer separaten Klasse Handhabung.

Dokumentation:

• AddHandler statement

• Shared access modifier

Public NotInheritable Class MainInterface 
    Private Sub New() 'No constructor. 
    End Sub 

    Public Shared Sub DisableAltF4(ByVal TargetForm As Form) 
     TargetForm.KeyPreview = True 
     AddHandler TargetForm.KeyDown, AddressOf Form_KeyDown 
    End Sub 

    Private Shared Sub Form_KeyDown(sender As Object, e As KeyEventArgs) 
     e.Handled = (e.Alt AndAlso e.KeyCode = Keys.F4) 
    End Sub 
End Class 

nun in jeder Form des Load Event-Handler können Sie tun:

Private Sub yourForm_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
    MainInterface.DisableAltF4(Me) 
End Sub 

---

Wie Olaf gesagt, Sie auch alle Formen von einer Basisklasse erben machen kann. Dies könnte jedoch ein wenig komplizierter werden, da Sie sowohl die yourForm.vb als auch die yourForm.Designer.vb Datei, die Sie von der Basisform erben möchten, mitteilen müssen.

Public Class BaseForm 
    Inherits Form 

    Protected Overrides Sub OnLoad(e As System.EventArgs) 
     MyBase.OnLoad(e) 
     Me.KeyPreview = True 
    End Sub 

    Protected Overrides Sub OnKeyDown(e As System.Windows.Forms.KeyEventArgs) 
     MyBase.OnKeyDown(e) 
     e.Handled = e.Handled OrElse (e.Alt AndAlso e.KeyCode = Keys.F4) 
    End Sub 
End Class 

In yourForm.vb:

Public Class yourForm 
    Inherits BaseForm 

    ...code... 
End Class 

In yourForm.Designer.vb:

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()> _ 
Partial Class yourForm 
    Inherits yourNamespace.BaseForm 

    ...code... 
End Class 

Answer 2

Sie sollten den entsprechenden CLOSE-Menüeintrag auch aus dem Systemmenü des Formulars entfernen, indem Sie einen Interop-Anruf RemoveMenu() verwenden. Dies deaktiviert alle Standardoptionen zum Schließen von Fenstern.

Natürlich können Sie Form.Close() in Ihrem Code aufrufen, um Ihr Formular zu schließen. Dies kann durch einen Click Event-Handler einer benutzerdefinierten Schaltfläche, eines Menüelements usw. ausgelöst werden. Zusätzlich können Sie eine System.Windows.Forms.IMessageFilter implementieren, um eine benutzerdefinierte Tastenfolge (anstelle von ALT + F4) zu handhaben, um Ihr Formular zu schließen, z. C + L + O + S + E.

Answer 3

Set KeyPreview = True und handhaben das KeyDown-Ereignis:

Private Sub Form1_KeyDown(sender As Object, e As KeyEventArgs) Handles Me.KeyDown 
    If e.Alt AndAlso e.KeyCode = Keys.F4 Then 
     e.Handled = True 
    End If 
End Sub 

Answer 4

Ganz einfach:

In C#

protected override bool ProcessCmdKey(ref Message msg, Keys keyData) 
{ 
    if (keyData == (Keys.Alt | Keys.F4)) 
    { 
     return true; // The key is manually processed 
    } 
    else 
     return base.ProcessCmdKey(ref msg, keyData); 
} 

In VB.Net

Protected Overrides Function ProcessCmdKey(ByRef msg As Message, ByVal keyData As Keys) As Boolean 
    If keyData = (Keys.Alt Or Keys.F4) Then 
     Return True 
    Else 
     Return MyBase.ProcessCmdKey(msg, keyData) 
    End If 
End Function