Verwenden von Wort-Wildcards, um nicht akzeptierte Änderungen zu finden

Question

Ich habe einige Word-Dokumente mit nicht akzeptierten, nachverfolgten Änderungen. Ich möchte sie akzeptieren, aber immer noch rot in meinen Dokumenten. Ich denke, ein guter Weg, dies zu tun wäre eine Platzhaltersuche für nicht akzeptierte Änderungen und ersetzen sie mit dem gleichen Text in rot, aber ich weiß nicht, ob dies möglich ist. Ich bin auch glücklich mit anderen Möglichkeiten, um mein Ziel zu erreichen, ohne Wildcards.

Answer 1

Das Anwenden der Formatierung auf Revisionen kann nicht mit dem Standard-Suchbefehl von Word & durchgeführt werden. Sie können jedoch ein Makro schreiben, das alle Revisionen auflistet und dann Formatierungen für alle Revisionen anwendet.

Es gibt einen Block Beitrag von Chris Rae, die ein Makro enthält, die Revisionen Standardformatierung konvertiert:

Enumerating edits on large documents (AKA converting tracked changes to conventional formatting)

Das Makro kann noch nicht genau das tun, was man braucht, aber es sollte fang an.

Als Referenz hier ist eine Kopie des Makros:

Sub EnumerateChanges() 
    Dim rAll As Revision 
    Dim dReport As Document 
    Dim dBigDoc As Document 

    Set dBigDoc = ActiveDocument 

    If dBigDoc.Revisions.Count = 0 Then 
     MsgBox "There are no revisions in the active document.", vbCritical 
    ElseIf MsgBox(“This will enumerate the changes in '" + dBigDoc.Name + "' in a new document and close the original WITHOUT saving changes. Continue?", vbYesNo) <> vbNo Then 
     Set dReport = Documents.Add 

     dBigDoc.Activate ' really just so we can show progress by selecting the revisions 
     dBigDoc.TrackRevisions = False ' Leaving this on results in a disaster 

     For Each rAll In dBigDoc.Revisions 
      ' Now find the nearest section heading downwards 
      Dim rFindFirst As Range, rFindLast As Range 
      Set rFindLast = rAll.Range.Paragraphs(1).Range 
      While Not IsNumberedPara(rFindLast.Next(wdParagraph)) 
       Set rFindLast = rFindLast.Next(wdParagraph) 
      Wend 
      ' Now head back up to the next numbered section header 
      Set rFindFirst = rFindLast 
      Do 
       Set rFindFirst = rFindFirst.Previous(wdParagraph) 
      Loop Until IsNumberedPara(rFindFirst) Or (rFindFirst.Previous(wdParagraph) Is Nothing) 
      ConvertNumberedToText rFindFirst 

      Dim rChangedSection As Range 
      Set rChangedSection = dBigDoc.Range(rFindFirst.Start, rFindLast.End) 
      ' Properly tag all the revisions in this whole section 
      Dim rOnesInThisSection As Revision 
      For Each rOnesInThisSection In rChangedSection.Revisions 
       rOnesInThisSection.Range.Select ' just for visual update 
       DoEvents ' update the screen so we can see how far we are through 
       If rOnesInThisSection.Type = wdRevisionDelete Then 
        rOnesInThisSection.Reject 
        With Selection.Range 
         .Font.ColorIndex = wdRed 
         .Font.StrikeThrough = True 
        End With 
        dBigDoc.Comments.Add Selection.Range, “deleted” 
       Else 
        If rOnesInThisSection.Type = wdRevisionInsert Then 
         rOnesInThisSection.Accept 
         With Selection.Range 
          .Font.ColorIndex = wdBlue 
         End With 
         dBigDoc.Comments.Add Selection.Range, “inserted” 
        End If 
       End If 
      Next 

      ' Now copy the whole thing into our new document 
      rChangedSection.Copy 
      Dim rOut As Range 
      Set rOut = dReport.Range 
      rOut.EndOf wdStory, False 
      rOut.Paste 
     Next rAll 

     ' There should end up being no numbered paragraphs at all in the 
     ' new doc (they were converted to text), so delete them 
     Dim pFinal As Paragraph 
     For Each pFinal In dReport.Paragraphs 
      If IsNumberedPara(pFinal.Range) Then 
       pFinal.Range.ListFormat.RemoveNumbers 
      End If 
     Next 

     dBigDoc.Close False 
    End If 
End Sub 

Sub ConvertNumberedToText(rOf As Range) 
    If InStr(rOf.ListFormat.ListString, “.”) > 0 Then 
     rOf.InsertBefore "Changes to section " + rOf.ListFormat.ListString + " " 
    End If 
End Sub 

Function IsNumberedPara(rOf As Range) As Boolean 
    If rOf Is Nothing Then ‘ if the document doesn’t have numbered sections, this will cause changes to be enumerated in the whole thing 
     IsNumberedPara = True 
    ElseIf rOf.ListFormat.ListString <> "" Then 
     If Asc(rOf.ListFormat.ListString) <> 63 Then 
      IsNumberedPara = True 
     End If 
    End If 
End Function