Printing längste seq in einem Array unter Verwendung perl

Question

Ich habe ein Array mit Sequenzen, wie unten gezeigt in es

my @a = qw(AAAA CGTGATG CGTGATTTGG); 

Ich möchte, um die Sequenz auszudrucken, die längsten in der Länge unter Verwendung von perl ist. So sollte ausgegeben werden

CGTGATTTGG 

#!/usr/bin/perl-w 
use strict; 
use warnings; 
use List::Util qw(min max); 

my %hash =(); 
my @a = qw(AAAA CGTGATG CGTGATTTGG); 

foreach(@a){ 
    print join("\t",$_,length($_)),"\n"; 
} 

Welche heraus druckt

AAAA 4 
CGTGATG 7 
CGTGATTTGG 10 

Ich möchte nur die seq mit der längsten Zeichenfolge drucken, die 10

ist, wie kann ich es tun

Dank

Answer 1

Eine einfache Lösung, die die erste der langen zurückgibt est Strings:

use List::Util qw(reduce); 

my $longest = reduce { length($a) >= length($b) ? $a : $b } @a; 

Eine einfache Lösung, die alle der längsten Strings zurück:

use List::Util qw(max); 

my $max_len = max map { length($_) } @a; 
my @longests = grep { length($_) == $max_len } @a; 

Answer 2

Verwenden Sie ein Schwartzian transform:

use strict; 
use warnings; 
use v5.10; 

my @sorted = map { $_->[0] } 
      sort { $a->[1] <=> $b->[1] } 
      map { [$_, length($_)] } 
      qw(AAAA CGTGATG CGTGATTTGG); 

say $sorted[-1]; 
say pop(@sorted); 

Answer 3

Hier ist der schnellste von der previous post zu diesem Thema :

sub longest { 
    my $max = -1; 
    my $max_ref; 
    for (@_) { 
     if (length > $max) { # no temp variable, length() twice is faster 
      $max = length; 
      $max_ref = \$_; # avoid any copying 
     } 
    } 
    $$max_ref 
}