SQL UPDATE von Gruppen

Question

Betrachte folgende Tabelle:

SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 
CREATE TABLE [dbo].[Product](
    [ProductID] [int] IDENTITY(1,1) NOT NULL, 
    [ProductCategory] [int] NOT NULL, 
    [ProductCategoryGuid] [uniqueidentifier] NULL, 
CONSTRAINT [PK_Product] PRIMARY KEY CLUSTERED 
(
    [ProductID] ASC 
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON) ON [PRIMARY] 
) ON [PRIMARY] 

GO 
SET IDENTITY_INSERT [dbo].[Product] ON 

GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (1, 2, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (2, 2, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (3, 2, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (4, 3, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (5, 4, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (6, 2, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (7, 3, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (8, 4, NULL) 
GO 
INSERT [dbo].[Product] ([ProductID], [ProductCategory], [ProductCategoryGuid]) VALUES (9, 4, NULL) 
GO 
SET IDENTITY_INSERT [dbo].[Product] OFF 
GO 

Daten sieht wie folgt aus:

ProductID ProductCategory ProductCategoryGuid 
1   2    NULL 
2   2    NULL 
3   2    NULL 
4   3    NULL 
5   4    NULL 
6   2    NULL 
7   3    NULL 
8   4    NULL 
9   4    NULL 

Was ich möchte, ist erreichen, aktualisieren [ProductCategoryGuid] Spalte, so dass alle Zeilen mit demselben Wert für [Product] wird den gleichen GUID-Wert in [ProductCategoryGuid] Spalte

zur Klarstellung:

GUID-Werte werden als Teil der Aktualisierung Abfrage mit NEWID() Funktion

Reihen mit ProduktID IN (1, 2, 3, 6) erzeugt wird GUID1

Reihen mit ProduktID IN hat (4, 7) haben GUID2

Reihen mit ProductID IN (5,8,9) haben GUID3

Answer 1

ich folgende Skript verwenden würde, die eine Tabelle Variable Liste der verschiedenen Kategorien zu speichern. Die gleiche Tabellenvariable hat eine GUID-Spalte mit dem Standardwert NEWID(). Am Ende des Skripts gibt es eine UPDATE Anweisung Tabellenvariablen als Quelle und dbo.Product Tabelle als Ziel:

DECLARE @Results TABLE (
    [ProductCategory] [int] NOT NULL, 
    [ProductCategoryGuid] [uniqueidentifier] NOT NULL DEFAULT (NEWID()) 
) 

INSERT @Results (ProductCategory) 
SELECT DISTINCT p.ProductCategory 
FROM dbo.Product p 

UPDATE p 
SET  ProductCategoryGuid = r.ProductCategoryGuid 
OUTPUT deleted.ProductCategoryGuid, inserted.ProductCategoryGuid 
FROM dbo.Product p 
INNER JOIN @Results r ON p.ProductCategory = r.ProductCategory 

Kommentar OUTPUT Klausel, wenn Sie nicht die alten und neuen Werte sehen wollen.

Update: eine Anweisung Lösung (es erfordert SQL2012 +)

;WITH CteUpdateProduct 
AS (
    SELECT *, FIRST_VALUE(NewGUID) OVER(PARTITION BY ProductCategory ORDER BY ProductID) AS NewProductCategoryGuid 
    FROM (
     SELECT p.*, NEWID() AS NewGUID 
     FROM dbo.Product p 
    ) x 
) 
UPDATE CteUpdateProduct 
SET  ProductCategoryGuid = NewProductCategoryGuid 
OUTPUT inserted.ProductID, inserted.ProductCategory, inserted.ProductCategoryGuid; 

Answer 2

WITH productCategories as (
    SELECT DISTINCT ProductCategory 
    FROM product 
), productCategoriesWithGuid as (
    SELECT ProductCategory, NEWID() ProductCategoryGuid 
    From productCategories 
) 
UPDATE product 
SET ProductCategoryGuid = pc.ProductCategoryGuid 
FROM Product p 
JOIN productCategoriesWithGuid pc on p.ProductCategory = pc.ProductCategory 

Diese Abfrage wird die unterschiedlichen Produktkategorien,

Erstellt eine GUID für jeden von ihnen,

Und schließlich Updates die Produkttabelle mit den GUIDs

Alles in einer Aussage.