Update mehrere Spalten mit für alle

Question

Ich versuche, Spalten für alle zu aktualisieren. Der festgelegte Teil der update-Anweisung wird erstellt und dann an die for all-Anweisung übergeben. Es kann mehrere Spalten im Set-Teil geben. Aber es wirft einen Fehler auf: "fehlendes Gleichheitszeichen". Irgendeine andere Methode, um das zu lösen?

DECLARE 
    V_COL_LIST VARCHAR2(4000); 
    type emp_t 
    IS 
    TABLE OF NUMBER; 
    emp_id emp_t; 
BEGIN 
    SELECT employee_id bulk collect 
    INTO emp_id 
    FROM employees 
    WHERE department_id=10; 

    V_COL_LIST:='SALARY=EMPLOYEE_ID'; 

    FORALL INDX IN 1..emp_id.count 
    UPDATE EMPLOYEES SET V_COL_LIST 
    WHERE EMPLOYEE_ID=emp_id(indx); 
END; 

Answer 1

Die von Ihnen verwendete Syntax wird nicht erkannt. Sie können hierzu dynamisches SQL verwenden. Ich sehe jedoch nicht warum Sie Gehalt zu employee_i d in SALARY=EMPLOYEE_ID einstellen. Bitte überprüfen Sie Ihre Logik.

Verwendung dynamischer SQL:

DECLARE 
    V_COL_LIST VARCHAR2(4000); 
    type emp_t 
    IS 
    TABLE OF NUMBER; 
    emp_id emp_t; 
BEGIN 
    SELECT employee_id bulk collect 
    INTO emp_id 
    FROM employees 
    WHERE department_id=10; 

    V_COL_LIST:='SALARY=1000'; 

    FORALL INDX IN 1..emp_id.count 
     execute immediate 'UPDATE EMPLOYEES SET ' || V_COL_LIST 
    ||' WHERE EMPLOYEE_ID=:1' using emp_id(indx); 
END; 
/

Wenn Sie wissen, welche Spalten, was zu setzen sind, nur du schlicht Update-

DECLARE 
    type emp_t 
    IS 
    TABLE OF NUMBER; 
    emp_id emp_t; 
BEGIN 
    SELECT employee_id bulk collect 
    INTO emp_id 
    FROM employees 
    WHERE department_id=10; 

    FORALL INDX IN 1..emp_id.count 
     UPDATE EMPLOYEES SET COL1 = 'ABC', COL2 = 'DEF' 
     WHERE EMPLOYEE_ID = emp_id(indx); 
END; 
/