Neo4j unabhängige Auswahl über mehrere Match-Klauseln

Question

Ich möchte mit neo4j die Benutzer auswählen, die Anzahl der Action-Filme, die sie angeschaut haben und wie viele dieser Action-Filme von jedem Benutzer von Roland Emmerich geleitet wurde.

habe ich versucht, in verschiedenen Formen, diese Abfrage:

match (u:User)-[:watched]->(m:Movie)-[belongs_to]->  
(Category{category_name:"Action"}) with count(m) as actionMovies, u 
match (m:Movie)<-[directed]-(Director{director_name:"Roland Emmerich"}) 
return u, count(m) as MoviesFromRE, actionMovies 

Aber die Ausführung der Abfrage nie beendet. Also nehme ich an, ich mache so etwas wie ein Cross Join.

Eigentlich erwarte ich, die erste Zählung unabhängig von der Sekunde zu haben, da sie bereits berechnet wird, wenn der Compiler zur zweiten Übereinstimmungsklausel kommt.

Hier ist der relevante db Ansicht

Vielen Dank für alle Anregungen und hilft

Ok nach Ziffer der Tippfehler und einschließlich Filme in loszuwerden:

match (u:User)-[:watched]->(m:Movie)-[:belongs_to]->  
(:Category{category_name:"Action"}) with count(m) as actionMovies, u, m 
match (m)<-[:directed]-(:Director{director_name:"Roland Emmerich"}) 
return u, count(m) as MoviesFromRE, actionMovies order by u.user_name 

Jetzt bekomme ich für ActionMovies immer 1. Ich denke es liegt daran, dass ich mich jetzt erstmal mit der Klausel von Movies zusammenfasse. Ich denke, ich brauche einen Weg, die Filme von der ersten Klausel zur zweiten zu bringen, aber nicht meine erste von ihnen zu gruppieren.

Answer 1

Der Grund, warum Sie immer 1 für actionMovies immer in dieser Klausel ist:

WITH COUNT(m) AS actionMovies, u, m 

Diese Klausel (teilweise) sagt: „Die Zahl der m Knoten für jedes einzigartiges Paar u und m Knoten zählen ". Dieser Zählwert muss immer 1.

sein Diese Abfrage sollte besser funktionieren:

MATCH (u:User)-[:watched]->(am:Movie)-[:belongs_to]->(:Category{category_name:"Action"}) 
WITH u, COLLECT(am) AS ams 
UNWIND ams AS m 
OPTIONAL MATCH (m)<-[dir:directed]-(:Director{director_name:"Roland Emmerich"}) 
RETURN u, COUNT(dir) AS MoviesFromRE, SIZE(ams) AS actionMovies 
ORDER BY u.user_name;