Kopieren ohne Namensraum mit Kriterien in Xslt

Question

Ich verwende diese Vorlage für das Kopieren ohne Namensraum:

<xsl:template match="*" mode="copy-no-namespaces"> 
    <xsl:element name="{local-name()}"> 
     <xsl:copy-of select="@*"/> 
     <xsl:apply-templates select="node()" mode="copy-no-namespaces"/> 
    </xsl:element> 
</xsl:template> 

<xsl:template match="comment()| processing-instruction()" mode="copy-no-namespaces"> 
    <xsl:copy/> 
</xsl:template> 

das funktioniert. Aber ich möchte, dass es ohne bestimmten Namespace und nicht mit allen Namespaces kopiert wird. Zum Beispiel möchte ich einige Namespaces wie http://test.com, http://test2.com ignorieren, sollte die Kopie nur diese Namespaces, nicht alle Namespace entfernen.

Beispiel:

<xs:schema xmlns:xxx="http://include.com" xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:zzz="http:test.com" > 
    <zzz:element> 
    </zzz:element> 

    <xxx:complexType> 
    </xxx:complexType> 
</xs:schema> 

Hier zzz Namespace entfernt werden sollen, sondern bewahren xxx als zzznur Matches http://test.com, so wird der Ausgang seiner

<xs:schema xmlns:xxx="http://include.com" xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
    <element> 
    </element> 

    <xxx:complexType> 
    </xxx:complexType> 
</xs:schema> 

Wie kann ich das erreichen?

Answer 1

Ich denke, Sie können zwischen dem Verschieben von Elementen in einen anderen (oder keinen) Namespace und Kopieren von Namespaces (d. H. Namespacedeklarationen) verwirren. Sie sollten nur die zzz: Präfix Elemente zu No-Namespace verschieben müssen - und nicht, wenn die Ausgabe eine mittlerweile redundante Namespace-Deklaration enthält:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:ns1="http:test.com" 
exclude-result-prefixes="ns1"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="ns1:*"> 
    <xsl:element name="{local-name()}"> 
     <xsl:copy-of select="@*"/> 
     <xsl:apply-templates/> 
    </xsl:element> 
</xsl:template> 

</xsl:stylesheet> 

---

P. S. Wenn Sie möchten, können Sie das gleiche tun, ohne Präfix erklärt:

<xsl:template match="*[namespace-uri()='http:test.com']"> 
    <xsl:element name="{local-name()}"> 
     <xsl:copy-of select="@*"/> 
     <xsl:apply-templates/> 
    </xsl:element> 
</xsl:template> 

Answer 2

eine Vorlage mit höherer Priorität Verwenden Sie Elemente in bestimmten Namensraum zu halten:

<xsl:template match="*" 
       mode="copy-no-namespaces"> 
    <xsl:element name="{local-name()}"> 
    <xsl:apply-templates select="node() | @*" mode="copy-no-namespaces"/> 
    </xsl:element> 
</xsl:template> 

<xsl:template match="xxx:*" xmlns:xxx="http://include.com" 
       mode="copy-no-namespaces"> 
    <xsl:element name="{name()}" namespace="{namespace-uri()}"> 
    <xsl:apply-templates select="node() | @*" mode="copy-no-namespaces"/> 
    </xsl:element> 
</xsl:template> 

<xsl:template match="node() | @*" 
       mode="copy-no-namespaces" 
       priority="-10"> 
    <xsl:copy> 
    <xsl:apply-templates select="node() | @*"/> 
    </xsl:copy> 
</xsl:template> 

Die erste Vorlage Streifen Namensräume aus Elementen, behält der zweite Namensraum http://include.com in Elemente und die letzte alles andere Kopien.

Die zweite Vorlage könnte xsl:copy anstelle von xsl:element verwenden, aber das würde alle Namespaces im Geltungsbereich kopieren, und Sie würden mit redundanten Namespacedeklarationen enden.