Warum Code Mail funktioniert nicht

Question

Set objCDOSYSMail = Server.CreateObject("CDO.Message") 
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration") 

Set Flds = objCDOSYSCon.Fields 
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "any mail" 
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "any password" 
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "any server" 
Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1 

Flds.update 

Set objCDOSYSMail.Configuration = objCDOSYSCon 

objCDOSYSMail.From = "any mail" 
objCDOSYSMail.To = "any mailid" 
'' // objCDOSYSMail.CC = "any mailid" 
objCDOSYSMail.Bcc = "any mailid"  
objCDOSYSMail.Subject = "feed back"      
objCDOSYSMail.HTMLBody = strBody 

objCDOSYSMail.Send 

Set objCDOSYSMail = Nothing 

'' // Response.redirect("thank.html") 
response.Write("saved") 

Answer 1

ändern

Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1

zu

Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

1 - wird über einen Pickup-Verzeichnis 2 seinding - wird über SMTP Senden

Suche bei deinen anderen Parametern versuchst du offensichtlich, über p zu senden ort 25.

Answer 2

Versuchen Sie, diese

 

    Dim objCDOSYSMail 
    Dim objCDOSYSCon 
    Dim Flds 

    Set objCDOSYSMail = Server.CreateObject("CDO.Message") 
    Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration") 
    Set Flds = objCDOSYSCon.Fields 

    With Flds 
    .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 

    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "any server" 

    .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 

    .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 

    .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "any mail" 

    .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "any password" 

    .Update 

    End With 

    Set objCDOSYSMail.Configuration = objCDOSYSCon 

    'Sending The Email 
    With objCDOSYSMail 
    .From = "any mail" 
     .To = "any mailid" 
     .Subject = "feed back"            
     .HTMLBody = "my Message" 
     .Send 

    End With 

    'Disposing Objects 

    Set objCDOSYSMail = Nothing 
    Set objCDOSYSCon = Nothing 
    Set Flds = Nothing 

Wenn Sie keine Fehlermeldung erhalten, überprüfen Sie das Fehlerprotokoll auf dem Server. Stellen Sie sicher, dass der Server E-Mails an den E-Mail-Server (SMTP-Server) weiterleiten kann. Dies kann durch Ausführen einer schnellen "TELNET-Sitzung" vom Webserver zum E-Mail-Server erfolgen. Einige SMTP-Server führen auch in der Absenderdomäne einen Reverse-DNS aus. Das hört sich vielleicht dumm an, aber überprüfe auch den Benutzernamen und das Passwort.

HINWEIS: Ihre Frage wurde abgelehnt, weil Sie Ihre Absicht nicht klar angegeben haben. Das nächste Mal sei "SPEZIFISCH" und nicht "PAZIFISCH" (wie das große Meer). Die meisten Leute, die hier herumhängen, sind entweder Profis oder versuchen zu sein, also versuche zumindest eins zu sein.

Answer 3

Sie könnten die open source library ajaxed dafür verwenden. Es erkennt die Komponente und Sie müssen sich nicht darum kümmern.

Vergessen Sie das Problem der richtige E-Mail-Komponente der Wahl (& Konfiguration der Installation). Ajaxed macht das für Sie. Es prüft, welche Komponenten auf dem Server installiert sind und verwendet die "beste". Bitte beachten Sie die API zu sehen, welche Komponenten derzeit unterstützt werden. Da diese Seite geschrieben wurde, wurde Jmail, ASPEmail und CDOSYS unterstützt.

Hier ist ein Tutorial, wie man send an email.