VBA-Formel von einer Arbeitsmappe zu einer anderen mit benannten Zellen

Question

Ich kann meine Formel nicht funktionieren. Sie können sehen, dass ich einfach versuche, einen Wert von einer anderen Arbeitsmappe in eine andere zu subtrahieren (es gibt eine Formel in den Zellen). Was vermisse ich? Es kopiert die Formel in die richtige Zelle, berechnet sie aber nicht. Ergebnisse #NAME ?.

Sub changeReports() 
    Dim currentWk As Worksheet 
    Dim prevYr As Worksheet 
    Dim prevWk As Worksheet 
    Dim File_Path As String 
    Dim Source_Workbook As Workbook 
    Dim Target_workbook As Workbook 

    File_Path = "B:\Operations\Aging 031416Wk11.xlsm" 
    Destination_Path = "B:\Operations\Aging 032116Wk12.xlsm" 
    Set Source_Workbook = Workbooks.Open(File_Path) 
    Set Target_workbook = Workbooks.Open(Destination_Path) 
    Set prevWk = Source_Workbook.Worksheets("2016 Reports") 
    Set currentWk = Target_workbook.Worksheets("2016 Reports")  
    currentWk.Activate 

    ' code works to insert formula in cell but formula not working the way it is written 
    Range("chgBox").formula = "=currentWk.Range(""grBox"")- prevWk.Range(""grBox"")"  
End Sub 

Answer 1

Wenn Sie das Ergebnis der Subtraktion in der Zelle Range ("chgBox") möchten, dann führen Sie die eigentliche Berechnung durch.

Range("chgBox") = currentWk.Range("grBox") - prevWk.Range("grBox") 

Wenn Sie die Formel möchten in der Range („chgBox“) Zelle bleiben dann die VBA Zelle Verweise auf Adressen konvertieren und eine Zeichenfolge verketten, die das Arbeitsblatt Formel darstellen.

Range("chgBox").Formula = "=" & currentWk.Range("grBox").Address(external:=true) & _ 
          "-" & prevWk.Range("grBox").Address(external:=true) 

Sie waren immer die #NAME! Fehler, da das Arbeitsblatt nicht versteht, was currentWk.Range(""grBox"") ist.

Nachtrag:

ich durch eine vollständige Probe Testumgebung ausgeführt haben und sowohl in der Formel und direktes Ergebnis der Arbeit, wie oben zur Verfügung gestellt. Ich habe den Rest des folgenden Codes aufgeräumt.

Option Explicit 

Sub changeReports() 
    Dim currentWk As Worksheet 
    Dim prevWk As Worksheet 
    Dim filePath As String, destinationPath As String 
    Dim sourceWorkbook As Workbook, targetWorkbook As Workbook 

    filePath = "B:\Operations\Aging 031416Wk11.xlsm" 
    destinationPath = "B:\Operations\Aging 032116Wk12.xlsm" 
    filePath = Environ("TMP") & "\Aging 031416Wk11.xlsm" 
    destinationPath = Environ("TMP") & "\Aging 032116Wk12.xlsm" 

    Set sourceWorkbook = Workbooks.Open(filePath) 
    Set targetWorkbook = Workbooks.Open(destinationPath) 
    Set prevWk = sourceWorkbook.Worksheets("2016 Reports") 
    Set currentWk = targetWorkbook.Worksheets("2016 Reports") 

    With currentWk 
     .Range("chgBox") = .Range("grBox") - prevWk.Range("grBox") 
     '.Range("chgBox").Formula = "=" & currentWk.Range("grBox").Address & _ 
          "-" & prevWk.Range("grBox").Address(external:=True) 
    End With 

    sourceWorkbook.Close savechanges:=False 
    targetWorkbook.Close savechanges:=True 

End Sub