Wählen SubQuery für Comma Separated Values ​​von einreihigen

Question

Aus einer Auswahlabfrage ich folgende Werte in einzelner Zeile immer, nicht in verschiedenen Reihen:

Id  Statuses 
---  ------------- 
1  Released,In Progress,Completed 

Jetzt mag ich eine Abfrage schreiben, so dass ich alle bekommen sollte die Aufträge, die in Status sind:

Select * from Orders where Status in (Select Statusesfrom StatusTable) 

Answer 1

Adopt einer dieser Splitter. Sie können Ihre eigene schreiben, aber Sie werden viel gegangen in der Erforschung dieser sehen:

http://www.sqlservercentral.com/articles/Tally+Table/72993/

Dieser Ihren Wert in eine Tabelle mit einer einzigen Spalte teilt. Sie können auf diesem verbinden, nachdem Sie die Funktion auf es wie laufen:

Select o.* from Orders o 
inner join splitTable s on o.keyColumn = s.Column 

Answer 2

Nach vielen Diskussionen (wie unten zu sehen) und die Prüfung, ich meine Parsing-Funktion geändert. Die neue Funktion analysiert 250.000 Strings und generiert 1.889.108 Zeilen in 400ms.

Declare @YourTable table (Id int,Statuses varchar(250)) 
Insert into @YourTable values 
(1,'Released,In Progress,Completed'), 
(2,'Released,In Progress') 

Select A.ID 
     ,B.* 
from @YourTable A 
Cross Apply (Select * from [dbo].[udf-Str-Parse-8K](A.Statuses,',')) B 
Order By ID,Key_PS 

Returns

ID Key_PS Key_Value Key_Pos 
1 1  Released 1 
1 2  In Progress 10 
1 3  Completed 22 
2 1  Released 1 
2 2  In Progress 10 

Die if UDF

benötigt

CREATE FUNCTION [dbo].[udf-Str-Parse-8K](@String varchar(8000), @Delimiter varchar(50)) 
Returns Table 
As 

--Usage: Select * from [dbo].[udf-Str-Parse-8K]('Dog,Cat,House,Car',',') 
--  Select * from [dbo].[udf-Str-Parse-8K]('John||Cappelletti||was||here','||') 
--  Select * from [dbo].[udf-Str-Parse-8K]('The quick brown fox',' ') 

Return (
    with cte1(N) As (Select 1 From (Values(1),(1),(1),(1),(1),(1),(1),(1),(1),(1)) N(N)), 
     cte2(N) As (Select Top (IsNull(DataLength(@String),0)) Row_Number() over (Order By (Select NULL)) From (Select N=1 From cte1 a, cte1 b, cte1 c, cte1 d) A), 
     cte3(N) As (Select 1 Union All Select t.N+DataLength(@Delimiter) From cte2 t Where Substring(@String,t.N,DataLength(@Delimiter)) = @Delimiter), 
     cte4(N,L) As (Select S.N,IsNull(NullIf(CharIndex(@Delimiter,@String,s.N),0)-S.N,8000) From cte3 S) 

    Select Key_PS = Row_Number() over (Order By A.N) 
     ,Key_Value = Substring(@String, A.N, A.L) 
     ,Key_Pos = A.N 
    From cte4 A 
) 

Nur ein paar Tweaks von http://www.sqlservercentral.com/articles/Tally+Table/72993/

Answer 3

Verwenden STRING_SPLIT() Funktion, wenn Sie SQL Server 2016 verwenden

 SELECT * 
    FROM Orders 
     WHERE Status IN (SELECT Value FROM StatusTable 
         CROSS APPLY STRING_SPLIT(Statuses,','))