NSIS Nach installierter App suchen

Question

Ich versuche zu überprüfen, ob eine App installiert ist, bevor ich meine installiere. Hier ist der Code ich verwende

; Check to see if already installed 
    ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{D9C50188-12D5-4D3E-8F00-682346C2AA5F}" "UninstallString" 
    IfFileExists $R0 +1 NotInstalled 
    MessageBox MB_OK|MB_TOPMOST "App Installed" 

Goto InstallCont2 

Es funktioniert, wenn der Name ein tatsächlicher Name ist, aber wenn der Name ist wie folgt:

{D9C50188-12D5-4D3E-8F00-682346C2AA5F}

dann erkennt es es nicht. Ich habe versucht, verschiedene "oder" in der Zeile, aber kann nicht den richtigen Code dafür finden.

Answer 1

Eine GUID im Pfad ist nicht wichtig.Wenn Sie den Wert nicht lesen können, könnte es ein 64-Bit-Problem sein und Sie könnten SetRegView benötigen. Process Monitor Lage zu helfen sein könnte, aber vor Debugging-Tool Ausgraben sollten Sie nur MessageBox mb_ok $R0 nach ReadRegStr tun, um zu sehen, ob es etwas zu lesen.

Sie können einfach nicht IfFileExists auf Strings aus UninstallString lesen nennen, da die Zeichenfolge enthalten könnte Anführungszeichen und/oder Befehlszeilenargumente, die Sie zuerst entfernen müssen

Yo Sie können so etwas verwenden, um nur den Pfad zu erhalten:

!macro GetAppPathFromCommandLine output input 
Push '${input}' 
Call GetAppPathFromCommandLine 
Pop ${output} 
!macroend 
Function GetAppPathFromCommandLine 
Exch $0 ; input 
Push $1 ; find 
Push $2 ; start offset 
Push $3 ; temp 
Push $4 ; pos 
StrCpy $1 ' ' 
StrCpy $2 "" 
StrCpy $3 $0 1 
StrCpy $4 -1 
StrCmp $3 '"' 0 +4 
StrCpy $1 $3 
StrCpy $2 1 
StrCpy $4 "" 
loop: 
IntOp $4 $4 + 1 
StrCpy $3 $0 1 $4 
StrCmp $3 "" done 
StrCmp $3 $1 done loop 
done: 
IntOp $4 $4 - $2 
StrCpy $0 $0 $4 $2 
Pop $4 
Pop $3 
Pop $2 
Pop $1 
Exch $0 
FunctionEnd 

Section 
!insertmacro GetAppPathFromCommandLine $0 'c:\foo\bar.exe' 
DetailPrint |$0| 
!insertmacro GetAppPathFromCommandLine $0 '"c:\foo bar\baz.exe"' 
DetailPrint |$0| 
!insertmacro GetAppPathFromCommandLine $0 'c:\foo\bar.exe param1 "pa ra m2" param3' 
DetailPrint |$0| 
!insertmacro GetAppPathFromCommandLine $0 '"c:\foo bar\baz.exe" param1 "pa ra m2" param3' 
DetailPrint |$0| 
SectionEnd