Prolog Get Liste aus verschiedenen Beziehungen

Question

Ich möchte eine Liste von einem Graphen erhalten. Die Variablen mit zwei Buchstaben sind die Punkte und der eine Buchstabe ist eine Linie. Jede Zeile kann mehrere Punkte enthalten.

conn(bs, oc, c). 
conn(oc, tc, c). 
conn(bs, gp, j). 
conn(gp, cc, j). 
conn(gp, pc, p). 
conn(pc, ls, p). 
conn(gp, oc, v). 
conn(oc, pc, b). 
conn(pc, cc, b). 
conn(tc, ls, n). 
conn(ls, cc, n). 

link(X, Y, Z) :- conn(X, Y, Z), !. 
link(X, Y, Z) :- conn(Y, X, Z). 

Jetzt möchte ich eine Liste mit allen Punkten einer Zeile erhalten. Durch die Eingabe von:

getpoints(c, X). 

würde ich

X = [bs, oc, tc] 

Dies ist zu erwarten, wie ich versuchte, meine Ergebnisse zu erhalten:

getpoints(Line, [First|[]]) :- not(link(First, _Second, Line)). 
getpoints(Line, [First|Rest]) :- link(First, _Second, Line), getpoints(Line, Rest). 

Hat jemand eine Idee?

Answer 1

Wenn Sie nicht daran interessiert, in einer bestimmten Reihenfolge der Punkte sind, könnten Sie setof/3

von Beispiel

getpoints(Line, Points) :- 
    setof(X, Y^(conn(X, Y, Line) ; conn(Y, X, Line)), Points). 

--- EDIT ---

Ist Es ist sehr kompliziert, die Reihenfolge der Punkte zu bekommen?

Wenn Sie Punkt sind wirklich eine Linie (keine allgemeine Grafik) sind, können Sie so etwas wie

nextLine(Line, EndLine, []) :- 
    \+ conn(EndLine, _, Line). 

nextLine(Line, Start, [NextPoint | NextLine]) :- 
    conn(Start, NextPoint, Line), 
    nextLine(Line, NextPoint, NextLine). 

getpoints(Line, [Start, NextPoint | NextLine]) :- 
    conn(Start, NextPoint, Line),  
    \+ conn(_, Start, Line), 
    nextLine(Line, NextPoint, NextLine). 

Die Idee finden, in getpoints/2, der Start Punkt der Linie schreiben können, das ist der Punkt, der links von conn/3 (conn(Start, NextPoint, Line)) liegt, aber nicht rechts von conn/3 (\+ conn(_, Start, Line)) steht.

Auf diese Weise haben Sie die ersten beiden Punkte der Zeile und beim rekursiven Aufruf von nextLine/3 erkennen Sie die folgenden Punkte in der richtigen Reihenfolge.