VBScript-Ausgabe zu Konsole

Question

Was ist der Befehl oder der schnellste Weg, um Ergebnisse mit vbscript zur Konsole auszugeben?

Answer 1

Sie meinen:

Wscript.Echo "Like this?" 

Wenn Sie das unter wscript.exe laufen (der Standard-Handler für die Erweiterung VBS, so was Sie bekommen, wenn Sie das Skript per Doppelklick) Sie bekommen " MessageBox "Dialog mit Ihrem Text drin. Wenn Sie das unter cscript.exe ausführen, werden Sie in Ihrem Konsolenfenster ausgegeben.

Answer 2

Ich weiß, das war vor einer Weile, aber vielleicht wird dies anderen helfen. Es wurde gefunden auf Dragon-IT Scripts and Code Repository.

Sie können dies mit den folgenden und bleiben Sie weg von den cscript/wscript Unterschiede und ermöglicht es Ihnen, die gleiche Konsole Ausgabe, die eine Batch-Datei haben würde. Dies kann hilfreich sein, wenn Sie VBS aus einer Stapeldatei aufrufen und diese nahtlos aussehen lassen müssen.

Set fso = CreateObject ("Scripting.FileSystemObject") 
Set stdout = fso.GetStandardStream (1) 
Set stderr = fso.GetStandardStream (2) 
stdout.WriteLine "This will go to standard output." 
stderr.WriteLine "This will go to error output." 

Answer 3

Sie müssen nur Cscript anstelle von Wscript erzwingen. Ich benutze immer diese Vorlage. Die Funktion ForceConsole() führt Ihre vbs in cscript aus, außerdem haben Sie einen netten Alias ​​zum Drucken und Scannen von Text.

Set oWSH = CreateObject("WScript.Shell") 
vbsInterpreter = "cscript.exe" 

Call ForceConsole() 

Function printf(txt) 
    WScript.StdOut.WriteLine txt 
End Function 

Function printl(txt) 
    WScript.StdOut.Write txt 
End Function 

Function scanf() 
    scanf = LCase(WScript.StdIn.ReadLine) 
End Function 

Function wait(n) 
    WScript.Sleep Int(n * 1000) 
End Function 

Function ForceConsole() 
    If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then 
     oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34) 
     WScript.Quit 
    End If 
End Function 

Function cls() 
    For i = 1 To 50 
     printf "" 
    Next 
End Function 

printf " _____ _ _   _____   _ _____   _  _ " 
printf "| _ |_| |_ ___ ___|  |_ _ _ _| | | __|___ ___|_|___| |_ " 
printf "|  | | '_| . | | --| | | | . | |__ | _| _| | . | _|" 
printf "|__|__|_|_,_|___|_|_|_____|_____|___| |_____|___|_| |_| _|_| " 
printf "              |_|  v1.0" 
printl " Enter your name:" 
MyVar = scanf 
cls 
printf "Your name is: " & MyVar 
wait(5) 

Answer 4

Ich kam in diesem Post und ging zu einem Ansatz zurück, die ich vor einiger Zeit verwendet, die auf @ MadAntrax des ähnlich ist.

Der Hauptunterschied besteht darin, dass eine benutzerdefinierte VBScript-Klasse verwendet wird, um die gesamte Logik für den Wechsel zu CScript und die Ausgabe von Text an die Konsole zu übernehmen, sodass das Hauptscript ein wenig sauberer wird.

Dies setzt voraus, dass es Ihr Ziel ist, die Ausgabe an die Konsole zu streamen, anstatt die Ausgabe an die Nachrichtenfelder zu senden.

Die cCONSOLE-Klasse ist unten. Um sie zu verwenden, fügen Sie die vollständige Klasse am Ende des Skripts ein und instanziieren Sie sie direkt am Anfang des Skripts. Hier ein Beispiel:

Option Explicit 

'// Instantiate the console object, this automatically switches to CSCript if required 
Dim CONS: Set CONS = New cCONSOLE 

'// Now we can use the Consol object to write to and read from the console 
With CONS 

    '// Simply write a line 
    .print "CSCRIPT Console demo script" 

    '// Arguments are passed through correctly, if present 
    .Print "Arg count=" & wscript.arguments.count 

    '// List all the arguments on the console log 
    dim ix 
    for ix = 0 to wscript.arguments.count -1 
     .print "Arg(" & ix & ")=" & wscript.arguments(ix) 
    next 

    '// Prompt for some text from the user 
    dim sMsg : sMsg = .prompt("Enter any text:") 

    '// Write out the text in a box 
    .Box sMsg 

    '// Pause with the message "Hit enter to continue" 
    .Pause 

End With  




'= =========== End of script - the cCONSOLE class code follows here 

Hier ist der Code für die cconsole Klasse

 CLASS cCONSOLE 
'= ================================================================= 
'= 
'= This class provides automatic switch to CScript and has methods 
'= to write to and read from the CSCript console. It transparently 
'= switches to CScript if the script has been started in WScript. 
'= 
'= ================================================================= 

    Private oOUT 
    Private oIN 


    Private Sub Class_Initialize() 
    '= Run on creation of the cCONSOLE object, checks for cScript operation 


     '= Check to make sure we are running under CScript, if not restart 
     '= then run using CScript and terminate this instance. 
     dim oShell 
     set oShell = CreateObject("WScript.Shell") 

     If InStr(LCase(WScript.FullName), "cscript.exe") = 0 Then 
      '= Not running under CSCRIPT 

      '= Get the arguments on the command line and build an argument list 
      dim ArgList, IX 
      ArgList = "" 

      For IX = 0 to wscript.arguments.count - 1 
       '= Add the argument to the list, enclosing it in quotes 
       argList = argList & " """ & wscript.arguments.item(IX) & """" 
      next 

      '= Now restart with CScript and terminate this instance 
      oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist 
      WScript.Quit 

     End If 

     '= Running under CScript so OK to continue 
     set oShell = Nothing 

     '= Save references to stdout and stdin for use with Print, Read and Prompt 
     set oOUT = WScript.StdOut 
     set oIN = WScript.StdIn 

     '= Print out the startup box 
      StartBox 
      BoxLine Wscript.ScriptName 
      BoxLine "Started at " & Now() 
      EndBox 


    End Sub 

    '= Utility methods for writing a box to the console with text in it 

      Public Sub StartBox() 

       Print " " & String(73, "_") 
       Print " |" & Space(73) & "|" 
      End Sub 

      Public Sub BoxLine(sText) 

       Print Left(" |" & Centre(sText, 74) , 75) & "|" 
      End Sub 

      Public Sub EndBox() 
       Print " |" & String(73, "_") & "|" 
       Print "" 
      End Sub 

      Public Sub Box(sMsg) 
       StartBox 
       BoxLine sMsg 
       EndBox 
      End Sub 

    '= END OF Box utility methods 


      '= Utility to center given text padded out to a certain width of text 
      '= assuming font is monospaced 
      Public Function Centre(sText, nWidth) 
       dim iLen 
       iLen = len(sText) 

       '= Check for overflow 
       if ilen > nwidth then Centre = sText : exit Function 

       '= Calculate padding either side 
       iLen = (nWidth - iLen)/2 

       '= Generate text with padding 
       Centre = left(space(iLen) & sText & space(ilen), nWidth) 
      End Function 



    '= Method to write a line of text to the console 
    Public Sub Print(sText) 

     oOUT.WriteLine sText 
    End Sub 

    '= Method to prompt user input from the console with a message 
    Public Function Prompt(sText) 
     oOUT.Write sText 
     Prompt = Read() 
    End Function 

    '= Method to read input from the console with no prompting 
    Public Function Read() 
     Read = oIN.ReadLine 
    End Function 

    '= Method to provide wait for n seconds 
    Public Sub Wait(nSeconds) 
     WScript.Sleep nSeconds * 1000 
    End Sub 

    '= Method to pause for user to continue 
    Public Sub Pause 
     Prompt "Hit enter to continue..." 
    End Sub 


END CLASS