XQuery: Namespace-Problem in lokalen Funktionen

Question

Ich habe das folgende Problem mit meiner lokalen Funktion.

Die folgende Funktion:

declare function local:exp($w as node()) as element()* { 
for $e in ($w/e) 
let $exp:= QName ("myns", "real") 
return 
    element {$exp}{ 
    attribute resource {$e/@lang} 
    } 
}; 

generiert diese xml:

<real xmlns="myns" resource="eng"/> 

Was wirklich gebraucht wird:

<myns:real rdf:resource="lang"/> 

Wie kann ich das achive?

1. Wie kann ich das Problem angehen?
2. Wie kann ich "rdf" als NS für Ressourcenattribut hinzufügen.

Vielen Dank im Voraus.

Answer 1

Sie können das Präfix der QName zuweisen so:

let $exp:= QName ("urn:my-namespace", "myns:real") 

wahrscheinlich der beste Weg, dies zu lösen, ist diese Namensräume in Ihrer Abfrage zu erklären und nur um sie durch Präfix verweisen:

declare namespace rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"; 
declare namespace myns="urn:my-namespace"; 

declare function local:exp($w as node()) as element()* { 
for $e in $w/e 
return 
    element myns:real { 
    attribute rdf:resource {$e/@lang} 
    } 
}; 

Beachten Sie, dass Ihre Funktion mithilfe direkter Konstrukteurs vereinfachen kann:

declare function local:exp($w as node()) as element()* { 
for $e in $w/e 
return <myns:real rdf:resource="{$e/@lang}" /> 
};