Cypher Abfrage, um alle E-Mails zu finden gesendet und erhalten einen Benutzer in neo4j

Question

Ich habe folgende Grafik in Neo4j erstellt.

(user1)-(:EMAIL_SENT)->(email)-[:EMAIL_TO)->(user2) 
(user1)<-(:EMAIL_TO)-(email)<-[:EMAIL_SENT)-(user2) 
(user1)-(:EMAIL_SENT)->(email)-[:EMAIL_TO)->(user3) 

Hier hat user1 zwei E-Mails gesendet und eine E-Mail erhalten. Ich möchte eine Abfrage erstellen, um alle von Benutzer1 gesendeten und empfangenen E-Mails sowie Informationen anderer Benutzer zu erhalten, die E-Mails von Benutzer1 gesendet und empfangen haben.

Ich habe diese Abfrage, aber es zeigt nur E-Mails empfangen. Ich möchte es erweitern, um auch E-Mail zu senden. Nicht sicher, wie man das macht

OPTIONAL MATCH (you:User)<-[:EMAIL_TO]-(Email), 
      (they:User)-[:EMAIL_SENT]->(Email) 
WHERE you.username = user1 
RETURN Email.text AS text, 
     Email.subject AS subject, 
     Email.id AS message_id, 
     they.username AS emailfrom, 
     you.username AS loggedinuser 

Answer 1

Als eine Option - zwei verschiedene Möglichkeiten.

1) Verwenden Sie union Kombination abfragen:

MATCH (U:User {username:'user1'})-[:EMAIL_SENT]->(E:email)-[:EMAIL_TO]->(R:User) 
RETURN E.text as text, 
     E.subject as subject, 
     id(E) as message_id, 
     U.username as emailfrom, 
     R.username as emailto 
UNION 
MATCH (U:User {username:'user1'})<-[:EMAIL_TO]-(E:email)<-[:EMAIL_SENT]-(R:User) 
RETURN E.text as text, 
     E.subject as subject, 
     id(E) as message_id, 
     R.username as emailfrom, 
     U.username as emailto 

2) Bestimmen Sie die Richtung der E-Mail basierend auf der Art der Beziehung:

MATCH (U:User {username:'user1'}) 
     -[L:EMAIL_SENT|EMAIL_TO]-(E:email)-[R:EMAIL_SENT|EMAIL_TO]- 
     (P:User) 
     WHERE type(L)<>type(R) 
RETURN E.text as text, 
     E.subject as subject, 
     id(E) as message_id, 
     U.username as user, 
     P.username as participator, 
     (CASE type(L) WHEN 'EMAIL_SENT' THEN 'out' ELSE 'in' END) as direction