Batch (.bat): Erhalte den Namen des ersten Skripts, nicht den aktuellen

Question

Ich habe first.bat und second.bat.

first.bat ist: call second.bat

Zweite ist: echo %~n0 (zeigt den Dateinamen der Ausführung Charge)

Der Ausgang ist Second.bat, aber ich will es den Anrufer Dateinamen angezeigt werden, nicht es selbst ist.

Ist das möglich?

Answer 1

Sie können es nicht für die Beschaffung von übergeordnetem Prozess-ID oder gibt etwas als Argument oder Umgebungsvariablen wie in KurzedMetal und Balic ohne komplizierten Systemaufruf tun Beiträge. Die involvierten Systemaufrufe sind detailliert in this post, Sie müssen DLL-Aufrufe in Stapel importieren, also ist es keine Kleinigkeit.

Answer 2

Shop der Wert %~n0 in einer Umgebungsvariable vor dem Aufruf second.bat

Answer 3

Ich denke, der einfachste Weg, dies zu tun wäre, den Dateinamen der ersten Charge als Parameter an die zweite übergeben, so.

REM First.bat 
call Second.bat %~n0 

REM Second.bat 
echo %1 

Hoffe, das hilft!

Answer 4

Dieser Ansatz erkennt den Namen des Anrufers Skript oder auch wenn es direkt von der Kommandozeile

@echo off 
setlocal DisableDelayedExpansion 
set "func=%~0" 
for /F "delims=\" %%X in ("%func:*\=%") do set "func=%%X" 
if ":" == "%func:~0,1%" (
    goto %func% 
) 
REM *** Get the name of the caller 
(
    (goto) 2>nul 
    setlocal DisableDelayedExpansion 
    call set "caller=%%~f0" 
    call set _caller=%%caller:*%%~f0=%% 
    if defined _caller (
     set "callType=batch" 
     call "%~d0\:mainFunc\..%~pnx0" %* 
    ) ELSE (
     set "callType=cmd-line" 
     cmd /c "call "%~d0\:mainFunc\..%~pnx0" %*" 
    ) 
    endlocal 
) 
echo NEVER REACHED 
exit /b 

:mainFunc 
echo :mainFunc of %~nx0 arg1=%1 is called from '%caller%'/%callType% 
exit /b 

Es nutzt die Tatsache genannt, dass eine (goto) Aussage einer Ebene aus dem Stapel entfernt werden.
Dies führt zum Verlassen der aktuellen Batch-Datei und %~f0 wird der Name des Aufrufers Skript (und %~0 die aktuelle Funktion dieser Charge) oder der Text %~f0 im Fall von von der Befehlszeile aufgerufen werden.

Dann wird das eigene Skript erneut aufgerufen mit "%~d0\:mainFunc\..%~pnx0"

Externe Script

Zur einfachen Verwendung Sie einen Helfer Batch-Datei hinzufügen könnte.
es in Ihren eigenen Skripten mit dieser Linie Verwenden

@echo off 
<:GetCaller <nul call GetCaller.bat myCallerVar 
echo This batch was called from "%myCallerVar%" 

Namen der Helfer Batch-Datei GetCaller.bat

@echo off 
setlocal DisableDelayedExpansion 
set "func=%~0" 
for /F "delims=\" %%X in ("%func:*\=%") do set "func=%%X" 
if ":" == "%func:~0,1%" (
    goto %func% 
) 

REM *** STEP1 
REM *** Get the filename of the caller of this script, needed for later restart that 
(
    (goto) 2>nul 
    setlocal DisableDelayedExpansion %= it could be reenabled by the GOTO =% 
    set "_returnVar=%~1" 
    call set "_lastCaller=%%~f0" 
    call set "_argToLastCaller=%%*" 
    call "%~d0\:Step2\..%~pnx0" %* 
) 
exit /b %= This is never reached =% 

:Step2 
REM *** STEP2 
REM *** Get the filename/cmd-line of the caller of the script 
(
    (goto) 2>nul 
    (goto) 2>nul 
    setlocal DisableDelayedExpansion %= it could be reenabled by the GOTO =%  
    set "_returnVar=%_returnVar%" 
    set "_lastCaller=%_lastCaller%" 
    set "_argToLastCaller=%_argToLastCaller%" 
    call set "caller=%%~f0" 
    call set _caller=%%caller:*%%~f0=%% 
    if defined _caller (
     set "callType=batch" 
     call "%~d0\:Step3batch\..%~pnx0" 
    ) ELSE (
     set "callType=cmd-line" 
     cmd /c "call "%~d0\:Step3batch\..%~pnx0" " 
    ) 
    endlocal 
) 
exit /b %= This is never reached =% 

:Step3batch 
REM *** STEP3 Restart the requester batch, but jump to the label :GetCaller 
call :GetCaller 
exit /b %= This is never reached =% 

:GetCaller 
REM *** This uses the trick, that starting a batch without CALL will jump to the last used label 
if "%_returnVar%" NEQ "" set "%_returnVar%=%_caller%" 
%_lastCaller% %_argToLastCaller% 

echo #6 never reached