Inno-Setup: Kontrollkästchen hinzufügen und Dateien herunterladen, wenn aktiviert

Question

Ich würde gerne wissen, wie Sie ein Kontrollkästchen vor Abschluss der Installation hinzufügen. Wenn dieses Kontrollkästchen aktiviert ist, sollten Dateien heruntergeladen werden. Dankbar.

Answer 1

Sie können eine benutzerdefinierte Options-Seite (CreateInputOptionPage) nach der Installationsseite erstellen (wpInstalling).

Und verwenden Sie Inno Download Plugin, um die heruntergeladene auszulösen, wenn der Benutzer so entscheidet.

Nach dem Hochladen, z.B. Wenn die "Completing" -Seite (wpFinished) angezeigt wird, führen Sie die heruntergeladene Anwendung aus.

[Code] 

#include "idp.iss" 

var 
    DownloadOptionPage: TInputOptionWizardPage; 

procedure InitializeWizard(); 
begin 
    DownloadOptionPage := 
    CreateInputOptionPage(wpInstalling, 
     'Additional download', 
     'Select what additional components do you want to download and install.', 
     '', False, False); 
    DownloadOptionPage.Add('Something'); 
    idpDownloadAfter(DownloadOptionPage.ID); 
end; 

function NextButtonClick(CurPageID: Integer): Boolean; 
begin 
    Result := True; 

    if CurPageID = DownloadOptionPage.ID then 
    begin 
    if DownloadOptionPage.Values[0] then 
    begin 
     idpAddFile(
     'https://www.example.com/something.exe', ExpandConstant('{tmp}\something.exe')); 
    end; 
    end; 
end; 

procedure CurPageChanged(CurPageID: Integer); 
var 
    FileName: string; 
    ResultCode: Integer; 
begin 
    if CurPageID = wpFinished then 
    begin 
    FileName := ExpandConstant('{tmp}\something.exe'); 
    if FileExists(FileName) then 
    begin 
     if not Exec(FileName, '', '', SW_SHOW, ewNoWait, ResultCode) then 
     begin 
     MsgBox(Format('Error executing %s', [FileName]), mbError, MB_OK); 
     end; 
    end; 
    end; 
end; 

---

Obwohl weder Inno Setup noch die Download-Plugin nicht wirklich etwas zu tun entworfen, nachdem die Installation abgeschlossen ist. Zum Beispiel ist die Schaltfläche "Abbrechen" ausgeblendet, so dass Sie den Download nicht abbrechen können. Und schlimmer noch, Sie können das Installationsprogramm nicht beenden, wenn der Download aus irgendeinem Grund fehlschlägt.

Es könnte wahrscheinlich herum gearbeitet werden.

Sie können jedoch stattdessen einen Standard-Workflow verwenden, bei dem alle Benutzeroptionen erfasst und Abhängigkeiten heruntergeladen werden vor die Installation.