Excel VBA Adresse finden und zuweisen, dann Wert wiederverwenden

Question

Ich versuche zu finden, wenn es einen bestimmten Titel für eine Zelle gibt, übergeben Sie die Adresse dieser Zelle an eine Variable und verwenden Sie diesen Speicherort, um die Größe der Spalte anzupassen. Der Grund, warum ich das mache, ist, weil ich mehrere Funktionen schreibe, die die Position der Spalten verschieben. Ich würde es begrüßen, wenn jemand einen Blick darauf werfen und mir sagen könnte, was ich falsch mache.

Option Explicit 

Sub adjustColumns() 

Dim PONumberCell As String 
Dim PONumberAddress As Range 
Dim TopLabelinColumn As Range 

For Each TopLabelinColumn In Range("A1:Z1").Cells 
    If TopLabelinColumn Like "PO_NUMBER" Then TopLabelinColumn.Value = "PO" 
    PONumberCell = TopLabelinColumn.Address 

    Set PONumberAddress = PONumberCell 
    PONumberAddress.ColumnWidth = 70 

Next TopLabelinColumn 

End Sub 

Answer 1

bearbeiten nach OP der weiteren Anfrage:

Sie ein Range-Objekt sind verwirrend (wie PONumberCell sollte sein) mit einem String Variable eines (wie PONumberAddress), so

Set PONumberAddress = PONumberCell 

funktioniert nicht, weil Sie eine object Variable auf einen String ein

zuweisen versuchen, aber Sie können effektiver sein sollte, die Schleife zu vermeiden und mit Hilfe der Find() Methode

Option Explicit 

Sub adjustColumns() 
    Dim PONumberAddress As String 
    Dim PONumberCell As Range 

    Set PONumberCell = Range("A1:Z1").Find(what:="PO_NUMBER", LookIn:=xlValues, lookat:=xlPart, MatchCase:=False) 
    If Not PONumberCell Is Nothing Then 
     With PONumberCell 
      .value = "PO" 
      PONumberAddress = .Address 
      .EntireColumn.ColumnWidth = 70 
     End With 
    Else 
     Set PONumberCell = Range("A1:Z1").Find(what:="PO", LookIn:=xlValues, lookat:=xlWhole, MatchCase:=False) '<--| if it didn't find "PO_NUMBER" then it seaches for a complete match of "PO" 
     If Not PONumberCell Is Nothing Then PONumberCell.EntireColumn.ColumnWidth = 70 
    End If 
End Sub 

Answer 2

die Kommentare über Folgen, gibt es ein paar erros im Code sind:

1. Einstellen der PONumberAddress Range, müssen Sie die Syntax verwenden: Set PONumberAddress = Range(PONumberCell) die Adress-String in Klammern gefunden mit .

2. Um die Spaltenbreite einzustellen, verwenden Sie: PONumberAddress.Columns.ColumnWidth = 70.

3. Nach Ihrem Beitrag, ich glaube, Sie für Spalten dies nur tun wollen, wo die Überschrift „PO_NUMBER“ ist, also Sie den Code alle unten benötigen inisde Ihre If: If TopLabelinColumn.Value Like "PO_NUMBER" Then.

-Code

Option Explicit 

Sub adjustColumns() 

Dim PONumberCell As String 
Dim PONumberAddress As Range 
Dim TopLabelinColumn As Range 

For Each TopLabelinColumn In Range("A1:Z1").Cells 
    If TopLabelinColumn.Value Like "PO_NUMBER" Then 
     TopLabelinColumn.Value = "PO" 
     PONumberCell = TopLabelinColumn.Address 

     Set PONumberAddress = Range(PONumberCell) 
     PONumberAddress.Columns.ColumnWidth = 70 
    End If 
Next TopLabelinColumn 

End Sub