Ersetzen Zeichenfolge durch einen neuen Wert

Question

Ich versuche eine riesige Datei (+5.000.000 Datensätze) zu manipulieren, so kann ich den Wert der 8. Spalte zum Beispiel ersetzen.

If $8 = 1 replace it with success 
if $8 = 2 replace it with check 
if $8 = null replace with undefined 

Hier ist ein Stück der Daten, die von einem , Zeichen getrennt ist:

"APPLICATION_ID","ORIGIN_ID","SERVICE_ID","PROVIDER_ID","RATING_ID","ATO","DATE","USER_TYPE","ESTATUS","OPERATION_ID" 

"3","2","424","5020","1058","3017292917","30/11/2016 01:14:25 a.m.","1","2004","14804862360104011458" 

Das Feld I ersetzt werden soll ist USER_TYPE$8

bei gelegen ich das versucht, aber es doesn‘ t ersetzen Sie die Werte:

awk '{if($8 = 1) print $1, $2, $3, $4, $5, $6, $7, "success", $9, $10}' input_file 

Wie kann ich das schaffen?

Answer 1

Hier ist eine kürzere Einzeiler:

$ awk 'BEGIN{FS=OFS=",";a[1]="success";a[2]="check"} {gsub(/"/,"",$8)} $8 in a{$8=a[$8]} 1' input.txt 

ausgebrochenen zur Kommentierung:

BEGIN { 
    FS=OFS=","  # set our field separators 
    a[1]="success" # populate an array with replacement values 
    a[2]="check" 
} 

{ 
    gsub(/"/,"",$8) # remove quotes in field 8, for easier processing 
} 

$8 in a {   # check to see if field 8 is a member of our array 
    $8=a[$8]   # replace field 8 with the contents of the array at that index 
} 

1     # print the line 

Wenn es wichtig ist, um jedes Feld die Zitate zu halten, können Sie das tun, indem Sie die Zuweisung mit einem sprintf() ersetzen das schließt sie ein:

Denken Sie daran, dass awk nur über Ihren Feldtrenner weiß, nicht Ihre Angebote. Wenn Sie ein Feld mit einem Komma im Feld in Anführungszeichen haben, wird es von awk als Feldtrennzeichen betrachtet. Sie könnten Schutz für diese Art von Vorkommen mit so etwas wie diesem an der Spitze der awk-Skript hinzu:

NF != 10 { print "ERROR: wrong number of fields in line",NR > "/dev/stderr"; exit(1) } 

Answer 2

@sandatomo: Versuchen (nicht getestet):

awk -F, -vs1="\"" 'NR>1{gsub(/\"/,"",$8);if($8==1){sub(/.*/,s1 "success" s1,$8)};if($8==2){sub(/.*/,s1 "check" s1,$8)};if($8=="null"){sub(/.*/,s1 "undefined" s1,$8)};print}' OFS=, Input_file 

EDIT: jetzt auch eine nicht einzeiler Form einer Lösung hinzuzufügen.

EDIT2: Ich habe meinen Code zuvor Code getestet und es hatte kein Feldtrennzeichen als "," so bearbeitet es jetzt.

EDIT3: Erklärung von oben.

awk -F, -vs1="\"" 'NR>1{         ##### Setting Field separator as comma(,). Creating a variable named s1 whose value is a quote("). Then Checking here if current line number is greater than 1. 
                  ##### If above condition is TRUE then all following statements will be executing. 
       gsub(/\"/,"",$8);       ##### substituting all quotes(") in $8 now. 
     if($8==1){         ##### Check if 8th field value is 1, if yes then it will execute following statement. 
       sub(/.*/,s1 "success" s1,$8)  ##### substitute everything in $8 with s1 "success" s1 
       }; 
       if($8==2){         ##### Similarly like above checking if $8's value is 2 
       sub(/.*/,s1 "check" s1,$8)  ##### Then substitute the $8's value with s1 "check" s1 
       }; 
       if($8=="null"){       ##### checking if $8's value is "null" here 
       sub(/.*/,s1 "undefined" s1,$8) ##### substituting the complete value of $8 with s1 "undefined" s1. 
         }; 
     print          ##### printing the whole line now. 
     } 
    ' OFS=, Input_file         ##### Setting output field separator as a comma. Then mentioning the Input_file here. 

Answer 3

Sie könnten so etwas wie dies versuchen:

awk 'BEGIN {OFS=FS=",";r["\"\""] = "\"undefined\""; r["\"1\""]= "\"success\""; r["\"2\""]="\"check\""} {if($8 in r) $8 = r[$8]} 1' input_file 

Erklärung

• die BEGIN Teile setzt einen Ersatz-Mapping in r auf. z.B. r["\"1\""]= "\"success\""; ist eine Karte des literalen Tokens "1" (a 1 mit den qoutes!) Zum literalen Wert "success" (auch einschließlich der Anführungszeichen!)
• zusätzlich FS und OFS gesetzt Komma als Eingangs- und Ausgangstrennzeichen im BEGIN Teil
• der Teil nach der Definition von r besteht aus einem Test zu verwenden, wenn der Wert des Feldes $8 ein Schlüssel in der Karte ist, wenn ja, dann wird das Feld $8 durch den in der Karte r für diesen Schlüssel
• definierten Wert ersetzt. Die Frage ist nicht 100% klar, wenn in der Spalte $8 nicht zugeordnete Werte vorhanden sind. Verwenden Sie diese daher als Ausgangspunkt für Ihre eigenen Experimente