Zugriff auf VBA - doppelte Eingabe verhindern

Question

Ich versuche Access integrierte msgbox über die Eingabe von doppelten Datensätzen zu vermeiden, indem Sie Einträge vor dem Update-Ereignis überprüfen. Code funktioniert, aber ein großes Problem - Sie können diese Datensätze nicht mehr bearbeiten. Jeder Weg, beides zu erreichen - erlauben Bearbeitungen und vermeiden Access msgbox?

Private Sub Form_BeforeUpdate(Cancel As Integer) 

Dim rs As Recordset 
Set rs = CurrentDb.OpenRecordset("MyTable", dbOpenDynaset) 

If Data_Changed Then 'Variable of Boolean that is set to True in Dirty event 

    If Not IsNull(ID_Field) Then 

     If MsgBox("You have done changes. you wish to save? ?" & vbCrLf & vBCrLf & "Click Yes for saving changes or NO for Undoing changes ! " & _ 
     , vbQuestion + vbOKCancel + vbDefaultButton1) = vbOK Then 

      rs.FindFirst "ID = " & Me.ID_Field 

      If Not rs.NoMatch Then 
       Cancel = True 
       MsgBox "Error. You cannot add another record with same ID!", vbCritical 
       DoCmd.RunCommand acCmdUndo 
       Exit Sub 
      End If 


     Else 

      DoCmd.RunCommand acCmdUndo 

     End If 

     Else 

      MsgBox "Error. you cannot save record with blank ID !", vbCritical 

      DoCmd.SetWarnings False 
      If Me.Dirty Then Me.Undo 
      DoCmd.SetWarnings True 

      Exit Sub 

     End If 

     Me.ID_Field.Locked = True 
     Me.Other_Field.Locked = True 

End If 

End Sub 

Answer 1

Angenommen, Ihre Primärschlüsselspalte lautet myPK.

Um ID_Field für alle außer dem aktuellen Datensatz zu überprüfen, verwenden Sie kein Recordset und FindFirst, verwenden Sie stattdessen DLookup.

Dim TestID as Long 
TestID = Nz(DLookup("ID_Field", "MyTable", "ID_Field = " & Me.ID_Field & _ 
        " AND myPK <> " & Nz(Me.myPK, 0)), 0) 
If TestID > 0 Then 
    ' Dupe 
Else 
    ' ok 
End If 

Sie müssen möglicherweise myPK als unsichtbares Textfeld zum Formular hinzufügen zu können, um seinen Wert lesen.

Answer 2

Ein "Schnappschuss" nimmt die Aufzeichnungen in ihrem aktuellen Zustand für z.B. Inspektion. Sie sind schreibgeschützt.

den Datensatz zu öffnen lesen/schreiben, verwenden dbOpenDynaset

Answer 3

die Einbau-Nachricht zu vermeiden, ist es am besten, das Form.OnError Ereignis zu verwenden.
Siehe: https://msdn.microsoft.com/en-us/library/office/ff836345.aspx

z. wie folgt:

Private Sub Form_Error(DataErr As Integer, Response As Integer) 

    ' Error 3022 = "Cannot add a duplicate value because of a key constraint..." 
    If DataErr = 3022 Then 
     MsgBox "Your duplicate warning", vbExclamation 
     ' Remove duplicate ID and set focus into ID control 
     Me!ID_Field = Null 
     Me!ID_Field.SetFocus 
     ' Dont't show default error message 
     Response = acDataErrContinue 
    Else 
     ' Other errors: show default error message 
     Response = acDataErrDisplay 
    End If 

End Sub