Wie kann ich den Inhalt einer Datei in Lisp in einer Liste lesen?

Question

Ich möchte den Inhalt einer Datei in eine Liste einlesen. Einige meiner bisherigen Versuche waren -

(defun get-file (filename) 
    (let ((x (open filename))) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (list line))) 
    (close x))) 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) (contents (list nil))) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (cons contents line))) 
    (close x) contents)) 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) (contents nil)) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (append contents line))) 
    (close x) contents)) 

Keiner von diesen funktioniert. Kann mir jemand einen Weg sagen? Oder noch besser - wie man alle Inhalte in ein Array bringt?

Answer 1

Wie wäre es

(defun get-file (filename) 
    (with-open-file (stream filename) 
    (loop for line = (read-line stream nil) 
      while line 
      collect line))) 

Answer 2

Wo sind die Probleme?

(defun get-file (filename) 
    (let ((x (open filename))) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (list line))) ; <-- you are not collecting, just doing 
    (close x)))     ; <- the function returns the value of CLOSE 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) 
     (contents (list nil))) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (cons contents line))) ; <-- again, the cons goes nowhere 
    (close x) contents))    ; <-- CONTENTS has never been changed 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) 
     (contents nil)) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (append contents line))) ; <- again the result goes nowhere 
    (close x) contents))     ; <-- CONTENTS has never been changed 

DO wird nur etwas für Nebenwirkungen ausführen.

COLLECT sammelt das Ergebnis und LOOP gibt beim Beenden eine Liste der gesammelten Werte zurück.

Wie bereits erwähnt, verwenden Sie WITH-OPEN-FILE statt OPEN/CLOSE. WITH-OPEN-FILE schließt die Datei beim Verlassen des dynamischen Bereichs. Nicht nur von einem normalen Ausgang, sondern auch bei Fehlerbedingungen mit UNWIND-PROTECT.

Wenn Sie den Inhalt einer Datei lesen möchten, können Sie READ-SEQUENCE verwenden. Mit den üblichen Problemen. Wenn Sie beispielsweise eine ASCII-Datei als Text in eine Zeichenfolge lesen, ist die Zeichenfolge möglicherweise kürzer als die Datei. Zum Beispiel repräsentiert Common Lisp intern CRLF mit einem einzelnen Zeichen auf Plattformen, auf denen CRLF Newline ist. Ein weiteres Beispiel: In Unicode-unterstützenden Implementierungen kann der UTF-8-Code in der Datei durch ein einzelnes Zeichen ersetzt werden.

Answer 3

Ich will hinzufügen, Bibliotheken in

bearbeiten noch einfacher, mit uiop, die in ASDF enthalten ist.

(uiop:read-file-lines "file.txt") 

https://github.com/fare/asdf/blob/master/uiop/stream.lisp#L445

hat auch

(uiop:read-file-string "file") 

---

Mit Alexandria's read-file-into-string und Split-Sequenz:

(alexandria:read-file-into-string "file.txt") 
(split-sequence:split-sequence #\Newline *) 

Mit str:

(str:lines (str:from-file "file.txt"))