Wie verwendet man jsonbuilder mit Sammlungen?

Question

Ich brauche eine json Meldung wie diese zu erstellen:

{ 
    success:true, 
    count:3, 
    data: [ 
    {id:1}, 
    {id:2}, 
    {id:3} 
    ] 
} 

ich dieses versucht

import groovy.json.* 

def tasks = [1, 2,3] 
def json = new JsonBuilder() 

json{ 
    success(true) 
    count(tasks.size()) 
    data { 
    tasks.each { 
     data(
     id: it   
    ) 
    } 
    } 
} 

JsonOutput.prettyPrint(json.toString()) 

haben, aber es funktioniert nicht. Kann mir jemand zeigen, wie es funktioniert?

Answer 1

Ich würde empfehlen, die Aufgabenliste in eine Liste der Form [[id: 1], [id: 2], [id: 3]] Transformation und dann „jsonizing“ es:

import groovy.json.JsonBuilder 

def tasks = [1, 2, 3] 
def json = new JsonBuilder() 

json{ 
    success(true) 
    count(tasks.size()) 
    data(tasks.collect {[id: it]}) 
} 

println json.toPrettyString() 

Ich ziehe es in der Regel die Datenstrukturen in Groovy Erzeugen eines ersten (zB Listen, Karten) und dann wandle ich sie in JSON um, auf diese Weise habe ich normalerweise mehr Kontrolle über die Daten, die serialisiert werden sollen, und ich muss keine Logik in den Serialisierungscode einbeziehen.

import groovy.json.JsonBuilder 

def tasks = [1, 2, 3] 

def data = [ 
    success: true, 
    count: tasks.size(), 
    data: tasks.collect {[id: it]} 
] 

def json = new JsonBuilder(data) 
println json.toPrettyString()