Wie referenziere ich Tabellen in Excel VBA?

Question

Ist es in Excel VBA möglich, eine benannte Tabelle zu referenzieren?

könnte hypothetisch sein ...

Sheets("Sheet1").Table("A_Table").Select 

Ich habe einige Erwähnung von Tabellen gesehen Objekt einer Liste zu sein, aber ich bin mir nicht sicher, ob das ist die gleiche ...

Answer 1

Vielleicht

Erstellen einer Tabelle

einen Bereich in eine Tabelle konvertieren beginnt mit dem gleichen Code kann Ihnen helfen, wie in Excel 2003 (wie in this answer beschrieben) :

Sub CreateTable() 
    ActiveSheet.ListObjects.Add(xlSrcRange, Range("$B$1:$D$16"), , xlYes).Name = _ 
     "Table1" 
     'No go in 2003 
    ActiveSheet.ListObjects("Table1").TableStyle = "TableStyleLight2" 
End Sub 

Answer 2

Darüber hinaus ist es bequem, Variablen zu Objekten zu definieren. Zum Beispiel

Sub CreateTable() 
    Dim lo as ListObject 
    Set lo = ActiveSheet.ListObjects.Add(xlSrcRange, Range("$B$1:$D$16"), , xlYes) 
    lo.Name = "Table1" 
    lo.TableStyle = "TableStyleLight2" 
    ... 
End Sub 

Sie werden es wahrscheinlich sofort vorteilhaft finden.

Answer 3

Zusätzlich zu den oben genannten, können Sie dies tun (wobei „YourListObjectName“ ist der Name der Tabelle):

Dim LO As ListObject 
Set LO = ActiveSheet.ListObjects("YourListObjectName") 

Aber ich denke, das funktioniert nur, wenn Sie eine Liste Objekt verweisen möchten, die auf ist das aktive Blatt.

Ich habe Ihre Frage gefunden, weil ich auf ein Listenobjekt (eine Tabelle) in einem Arbeitsblatt verweisen wollte, auf das sich eine Pivot-Tabelle in einem anderen Arbeitsblatt bezieht. Da Listenobjekte Teil der Worksheets-Auflistung sind, müssen Sie den Namen des Arbeitsblatts kennen, auf dem sich das Listenobjekt befindet, um darauf Bezug zu nehmen. Um den Namen des Arbeitsblatts zu erhalten, auf dem sich das Listenobjekt befindet, erhielt ich den Namen des Quelllistenobjekts der Pivot-Tabelle (wiederum eine Tabelle) und durchblätterte die Arbeitsblätter und ihre Listenobjekte, bis ich das Arbeitsblatt gefunden hatte, das die Liste enthielt Objekt, nach dem ich gesucht habe.

Public Sub GetListObjectWorksheet() 
' Get the name of the worksheet that contains the data 
' that is the pivot table's source data. 

    Dim WB As Workbook 
    Set WB = ActiveWorkbook 

    ' Create a PivotTable object and set it to be 
    ' the pivot table in the active cell: 
    Dim PT As PivotTable 
    Set PT = ActiveCell.PivotTable 

    Dim LO As ListObject 
    Dim LOWS As Worksheet 

    ' Loop through the worksheets and each worksheet's list objects 
    ' to find the name of the worksheet that contains the list object 
    ' that the pivot table uses as its source data: 
    Dim WS As Worksheet 
    For Each WS In WB.Worksheets 
     ' Loop through the ListObjects in each workshet: 
     For Each LO In WS.ListObjects 
      ' If the ListObject's name is the name of the pivot table's soure data, 
      ' set the LOWS to be the worksheet that contains the list object: 
      If LO.Name = PT.SourceData Then 
       Set LOWS = WB.Worksheets(LO.Parent.Name) 
      End If 
     Next LO 
    Next WS 

    Debug.Print LOWS.Name 

End Sub 

Vielleicht weiß jemand einen direkteren Weg.

Answer 4

Das OP fragte, ist es möglich, Referenz eine Tabelle, nicht, wie Sie eine Tabelle hinzufügen. So ist die Arbeits Äquivalent

Sheets("Sheet1").Table("A_Table").Select 

würde diese Aussage sein:

Sheets("Sheet1").ListObjects("A_Table").Range.Select 

oder Teile zu wählen (wie nur die Daten in der Tabelle):

Dim LO As ListObject 
Set LO = Sheets("Sheet1").ListObjects("A_Table") 
LO.HeaderRowRange.Select  ' Select just header row 
LO.DataBodyRange.Select   ' Select just data cells 
LO.TotalsRowRange.Select  ' Select just totals row 

Für die Teile, Sie Möglicherweise möchten Sie die Existenz der Kopfzeilen- und Summenzeilen testen, bevor Sie sie auswählen.

Und ernsthaft, das ist die einzige Frage zum Verweisen auf Tabellen in VBA in SO? Tabellen in Excel machen so viel Sinn, aber es ist so schwer mit VBA zu arbeiten!

Answer 5

Die "richtige" Möglichkeit, eine Tabelle zu referenzieren, besteht darin, ihr ListObject aus ihrem Worksheet zu beziehen, d. H. SheetObject.ListObjects(ListObjectName).Wenn Sie eine Tabelle referenzieren möchten, ohne das Blatt zu verwenden, können Sie einen Hack Application.Range(ListObjectName).ListObject verwenden.

HINWEIS: Dieser Hack beruht auf der Tatsache, dass Excel erstellt stets einen benannten Bereich für die DataBodyRange mit dem gleichen Namen der Tabelle als die Tabelle. Allerdings kann dieser Bereichsname geändert werden ... obwohl es nicht etwas ist, was Sie tun möchten, da der Name zurückgesetzt wird, wenn Sie den Tabellennamen bearbeiten! Sie könnten auch einen benannten Bereich ohne zugeordnete ListObject erhalten.

Da Excel nicht-sehr-nützlich 1004 Fehlermeldung, wenn Sie den Namen falsch, möchten Sie vielleicht einen Wrapper erstellen ...

Public Function GetListObject(ByVal ListObjectName As String, Optional ParentWorksheet As Worksheet = Nothing) As Excel.ListObject 
On Error Resume Next 

    If (Not ParentWorksheet Is Nothing) Then 
     Set GetListObject = ParentWorksheet.ListObjects(ListObjectName) 
    Else 
     Set GetListObject = Application.Range(ListObjectName).ListObject 
    End If 

On Error GoTo 0 'Or your error handler 

    If (Not GetListObject Is Nothing) Then 
     'Success 
    ElseIf (Not ParentWorksheet Is Nothing) Then 
     Call Err.Raise(1004, ThisWorkBook.Name, "ListObject '" & ListObjectName & "' not found on sheet '" & ParentWorksheet.Name & "'!") 
    Else 
     Call Err.Raise(1004, ThisWorkBook.Name, "ListObject '" & ListObjectName & "' not found!") 
    End If 

End Function 

auch einige gute Listobject Info here.