Löschen Sie Zeilen in Excel basierend auf Duplikaten in Spalte

Question

Ich möchte die Zeilen in Excel basierend auf doppelte Werte in einer Spalte löschen. Nehmen wir an,

Column A  Column B 
ABC    1 
DEF    2 
DEF    3 
ABC    1 

In Spalte B, haben wir einen doppelten Wert. Gehen Sie nur mit der Funktion zum Entfernen von Duplikaten nicht weiter.

Answer 1

Nun, funktioniert dieser Code perfekt

ActiveSheet.Range("$A$1:$B$4").RemoveDuplicates Columns:=Array(1, 2), Header:=xlNo 

Answer 2

Vielleicht nicht die optimale Lösung, aber es macht die Arbeit

Public Sub DeleteDuplicates() 
    Dim rng As Range, cell As Range, find As Range, previous As Range 
    Set rng = Worksheets("Test").Range("A:A") 

    ' For each cell of the column 
    For Each cell In rng 
     ' Check duplicates only if the cell is not empty 
     If Trim(cell) <> "" Then 
      ' Search for the same value in column A 
      Set find = rng.find(What:=cell, After:=cell, LookAt:=xlWhole, MatchCase:=True) 
      ' if a result is found 
      If Not find Is Nothing Then 
       Do 
        Set previous = Nothing 
        ' If the column B is the same, save the row as "to be deleted" 
        ' The delete is not now otherwise the FindNext won't work 
        If find.Offset(, 1) = cell.Offset(, 1) Then 
         Set previous = find 
        End If 

        Set find = rng.FindNext(find) 

        ' If a duplicate was found, delete the raw 
        If Not previous Is Nothing Then 
         previous.EntireRow.Delete 
        End If 

        ' if no more duplicate, exit the do loop 
        If find Is Nothing Then 
         Exit Do 
        End If 

        ' if address of the result is the same as the clel, exit the do loop 
        If cell.Address = find.Address Then 
         Exit Do 
        End If 
       Loop While True 
      End If 
     End If 
    Next 
End Sub