Maple, maximaler Wert einer numerischen Funktion

Question

Ich versuche, den maximalen Wert der Lösung eines Systems mit zwei ODEs mit Maple zu berechnen. Ich habe zunächst gelöst, das System selbst:

> with(DEtools):with(plots): 
> a1:=0.00875;a2:=0.075;b1:=7.5;b2:=2.5;d1:=0.0001;d2:=0.0001;g:=4*10^(-8);K1:=5000;K2:=2500;n:=2;m:=2; 

> dsol:= dsolve({ 
diff(x(t), t) = a1+b1*x(t)^n/(K1^n+x(t)^n)-g*x(t)*y(t)-d1*x(t), 
diff(y(t), t) = a2+b2*x(t)^m/(K2^m+x(t)^m)-d2*y(t), 
x(0) = 1000, y(0) = 1000}, numeric, output = listprocedure); 

> xt:= eval(x(t), dsol); 
yt:= eval(y(t), dsol); 


> X:=plot(xt(t),t=0..50000,color=blue,legend="x(t)"): 
Y:=plot(yt(t),t=0..50000,color=green,legend="y(t)"): 
> display([X,Y]); 

ich die Lösungen des Systems auf xt und yt bekam, aber sie sind numerische Lösungen. Daher ist die Funktion von Maple maximize() nicht:

> maximize(xt); 
> maximize(xt(t),t=0..20000); 

Ist es möglich, den maximalen Wert einer numerischen Funktion mit Maple zu berechnen?

Answer 1

Ihre beiden Kurven xt und yt haben jeweils ein einzelnes lokales Maximum in Ihrem Bereich von t=0..50000, so können Sie das Optimization Paket für diesen auf einfache Art und Weise nutzen.

restart; 
with(plots): 
a1:=0.00875: a2:=0.075: b1:=7.5: b2:=2.5: d1:=0.0001: 
d2:=0.0001: g:=4*10^(-8): K1:=5000: K2:=2500: n:=2: m:=2: 
dsol:= dsolve({diff(x(t),t)=a1+b1*x(t)^n/(K1^n+x(t)^n)-g*x(t)*y(t)-d1*x(t), 
       diff(y(t),t)=a2+b2*x(t)^m/(K2^m+x(t)^m)-d2*y(t), 
       x(0)=1000, y(0)=1000}, numeric, output=listprocedure): 
xt:= eval(x(t), dsol): 
yt:= eval(y(t), dsol): 
X:=plot(xt(t), t=0..50000, color=blue, legend="x(t)"): 
Y:=plot(yt(t), t=0..50000, color=green, legend="y(t)"): 
xmax:=Optimization:-Maximize(xt, 0..50000): 
[xmax[2][1],xmax[1]]; 

       [9460.78688552799, 11193.0618953179] 

ymax:=Optimization:-Maximize(yt, 0..50000): 
[ymax[2][1],ymax[1]]; 

       [21471.8648785947, 19006.6009784691] 

display(Y, pointplot([[ymax[2][1],ymax[1]]], symbolsize=20), 
     X, pointplot([[xmax[2][1],xmax[1]]], symbolsize=20)); 

Für Ihr einfaches Beispiel funktioniert dies recht gut.

Wenn Ihr xt oder yt viele lokale Maxima hatte Sie könnten versuchen Maximize mit seiner method=branchandbound Option aufrufen.

Und dann gibt es andere Ansätze, wo Sie Ihr DE-System mit neuen abhängigen Variablen wie sagen könnte, xd(t)=diff(x(t),t) (zusammen mit geeigneten ICs) und dsolve/numeric selbst zu bemerken, wenn das Null wird (ein Extrempunkt) mit die events Einrichtungen, oder verwenden Sie fsolve darauf.