Kopieren von Daten aus Textdatei in Excel

Question

Hier ist der Code zum Kopieren der Daten aus einer Textdatei und Einfügen in Excel. Ich habe den Text durch vbNewline geteilt, aber ich muss es auch durch den Raum teilen.

Gibt es eine alternative Methode zum Aufteilen der Daten nach Speicherplatz, und wie teilt man die Daten durch vbNewLineund Speicherplatz?

On Error Resume Next 

Dim objFSO, strTextFile, strData, strLine, arrLines 

Const ForReading = 1 

path = InputBox("Enter the path :","Select Your Path !","Type your path here") 

'name of the text file 
strTextFile = path 

'Create a File System Object 
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject") 

'Open the text file - strData now contains the whole file 
strData = objFSO.OpenTextFile(strTextFile, ForReading).ReadAll 

'typesplit=inputbox("Enter the type ","Type to split(VbnewLine (or) <Space>)","vbnewline/space") 

'Split the text file into lines 
arrLines = Split(strData, vbNewLine) 

Set objExcel = CreateObject("Excel.Application") 
objExcel.Visible = True 
objExcel.Workbooks.Add 

intRow = 2 
k = 0 

align = InputBox("Enter the type of alignment...(default/horizontal/vertical)", _ 
     "Press h (or) v (or) d") 

If (align = "v") Then 
    rowlimit = InputBox("Enter the row limit") 
    For i=1 To 10 Step 1 
    For j=1 To rowlimit Step 1 
     objExcel.Cells(j, i).Value = arrLines(k) 
     k = k+1 
    Next 
    Next 
End If 

If (align = "h") Then 
    collimit = InputBox("Enter the col limit") 
    For i=1 To 10 Step 1 
    For j=1 To collimit Step 1 
     objExcel.Cells(i, j).Value = arrLines(k) 
     k = k+1 
    Next 
    Next 
End If 

MsgBox("Conversion Finished !!") 

Set objFSO = Nothing 

Answer 1

VBScript ermöglicht es Ihnen nicht, eine Zeichenfolge in einem Schritt durch mehrere Trennzeichen zu teilen. Sie müssen es nach dem ersten Trennzeichen aufteilen, dann das resultierende Array durchlaufen und die Teilzeichenfolgen nach dem zweiten Trennzeichen aufteilen usw.

For Each line In Split(strData, vbNewLine) 
    For Each word In Split(line, " ") 
    'do something with each word 
    Next 
Next 

Wenn Sie alle Wörter in einem einzelnen Array setzen für eine spätere Verarbeitung Sie sie in eine dynamisch veränderbare Array setzen würde:

ReDim words(-1) 'define empty resizable array 
For Each line In Split(strData, vbNewLine) 
    For Each word In Split(line, " ") 
    ReDim Preserve words(UBound(words)+1) 
    words(UBound(words) = word 
    Next 
Next 

Alternativ könnten Sie eine ArrayList verwenden:

Set words = CreateObject("System.Collections.ArrayList") 
For Each line In Split(strData, vbNewLine) 
    For Each word In Split(line, " ") 
    words.Add word 
    Next 
Next 

Beachten Sie, dass dynamische VBScript-Arrays bei großen Datenmengen schlecht arbeiten, da der Interpreter bei jeder Größenänderung des Arrays ein neues Array erstellt und alle Daten aus dem exi kopiert Stachelarray, weist dann der Variablen das neue Array zu.

Auf der anderen Seite bedeutet die Instanziierung eines ArrayList Objekts eine Menge Overhead, so dass es nicht so gut funktioniert wie VBScript eingebaute Arrays für kleine Datenmengen.