bat Dateien zum Verschieben von Dateien in Monatsordner basierend auf dem Dateinamen

Question

Ich habe Dateien in einem Ordner (C:/location1). Die Dateien sind wie:

A-14-0005 - Title1 - 06202017.pdf 
B-14-1111 - Title2 - 06202017.pdf 
B-15-7676 - Title3 - 06202017.pdf 

ich diese an einen anderen Ort verschieben müssen (c:/location2). Wenn der aktuelle Monat Januar ist, erstellen Sie den Ordner 2017 (für dieses Jahr) und erstellen Sie den Unterordner JANUARY. Wenn der aktuelle Monat Juni ist, erstellen Sie den Unterordner JUNE. Dann verschiebe die 3 Dateien in diesen Ordner.

Ich habe noch keine Batch-Datei geschrieben und suche nach Hilfe/Ideen zum Erstellen einer, um diese Aufgabe zu starten. Irgendwelche Links wo sonst als Tutorial für mich zu beginnen wird auch großartig sein. Dank

Answer 1

@echo off 
set month-num=%date:~3,2% 
set year-num=%date:~6,10% 
IF "%month-num:~0,1%"=="0" SET month-num=%month-num:~1% 
FOR /f "tokens=%month-num%" %%a in ("January February March April May June July August September October November December") do set mo-name=%%a 

if not exist "C:\location2\%year-num%" md C:\location2\%year-num%\%mo-name%" 
copy "C:\location1\A-14-0005 - Title1 - 06202017.*" "C:\location2\%year-num%\%mo-name%\" /y 
copy "C:\location1\B-14-1111 - Title2 - 06202017.*" "C:\location2\%year-num%\%mo-name%\" /y 
copy "C:\location1\B-15-7676 - Title3 - 06202017.*" "C:\location2\%year-num%\%mo-name%\" /y 
pause 

Answer 2

@Echo off&SetLocal EnableExtensions EnableDelayedExpansion 
Set "Dir1=c:\location1" 
Set "Dir2=c:\location2" 

:: Build Mon[01..12] array 
Set Cnt=100 
For %%A in (Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec 
) Do Set /A Cnt+=1&Set Mon[!Cnt:~-2!]=%%A 
::Set Mon[ 

For /f "delims=" %%A in (
    ' Dir /B/A-D "%Dir1%\?-??-???? - * - *.pdf" ^|findstr "[01][0-9][0-3][0-9]20[0-9][0-9]\.pdf$" ' 
) Do (
    Set "File=%%~nA" 
    Call Set "MoveTo=%Dir2%\!File:~-4!\%%Mon[!File:~-8,2!]%%\" 
    MD "!MoveTo!" >Nul 2>&1 
    Move "%%~fA" "!MoveTo!" 
) 

Beispiel Baum des Ergebnisses:

> Tree /F . 
C:\LOCATION2 
└───2017 
    └───Jun 
      B-15-7676 - Title3 - 06202017.pdf 
      B-14-1111 - Title2 - 06202017.pdf 
      A-14-0005 - Title1 - 06202017.pdf