Wie IPV4-Variable in CMD und Ping in neuen CMD-Fenster greifen

Question

Also hier ist die Idee, Ich versuche, eine Variable von Cmd wie IPv4 greifen und in der Lage sein, es in einem neuen Fenster zu pingen.

Was wäre die Logik, wenn Sie einen Befehl ausführen und einen bestimmten Teil dieses Befehls abrufen und in einer neuen Befehlszeile als neue Variable eingeben können, damit er eine Aktion ausführen kann.

Ein weiteres Beispiel:

1. Suche Computername.
2. Führen Sie den Befehl auf eine Zahl am Ende des Computernamens aus.

Ich lade gerade Visual Basic-Software herunter, da es so aussieht, als könnte es die Sprache sein, die ich brauche, aber sehr verwirrt.

Hat jemand irgendeine Grundidee, was ich verwenden oder ein Beispiel dafür haben kann?

Answer 1

Sie können so etwas versuchen:

@Echo off 
Color 0A & Mode con cols=80 lines=15 
Title How to grab IPv4 
::********************************** 
::Method1 
::********************************** 
echo( 
echo Method 1 with arp -a 
echo( 
For /f "tokens=2 delims= " %%a in ('arp -a ^|findstr /i "Interface"') do (set IP=%%a) 
Echo The Local IPv4 adress is : %IP% 
pause 
Cls 
Call:PingHost %IP% 
pause 
::********************************** 
::Method2 
::********************************** 
cls 
echo( 
echo Method 2 with ipconfig 
for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do (
    set ip=%%b 
) 
set ip=%ip:~1% 
echo( 
echo The Local IPv4 adress is : %ip% 
pause 
Cls 
Call:PingHost %IP% 
pause 
::********************************** 
::Method3 by Stephan 
::********************************** 
cls 
echo( 
echo Method 3 with %%computername%% = %computername% 
for /f "tokens=2 delims=[]" %%i in ('ping -4 -n 1 %computername%') do set ip=%%i 
echo( 
echo The Local IPv4 adress is : %ip% 
pause 
Cls 
Call:PingHost %IP% 
Pause 
exit 
::********************************** 
:Pinghost 
Start "%1" Ping %1 
exit /b 
::**********************************