Wie kann ich eine TXT-Datei aus Stapel bearbeiten lassen?

Question

So gerade jetzt, ich versuche herauszufinden, wie eine TXT-Datei durch den Benutzer des Batch-Programms bearbeitet werden kann. Ich habe bereits die Batchdatei, die die Datei erstellt, aber jetzt muss ich es so machen, dass die TXT-Datei hat, was der Benutzer für die Frage beantwortet hat. Hier ist, was ich habe jetzt:

@echo off 
echo Welcome to the Space Mapping Discord Report Maker 
pause 
echo Made by N3ther, version 0.1 ALPHA 
pause 
@echo off 
break>"%userdomain%\%username%\Desktop\report.txt" 
echo Question 1: What is your username on Discord?` 

(Es ist für einen Bericht maker ich Moderator auf bin.)

Answer 1

Es sieht aus wie etwas wie unten ist, was Sie brauchen:

@echo off 
setlocal EnableExtensions EnableDelayedExpansion 
set "ReportFile=%USERPROFILE%\Desktop\report.txt" 
del "%ReportFile%" 2>nul 

echo Welcome to the Space Mapping Discord Report Maker 
echo/ 
echo Made by N3ther, version 0.1 ALPHA 
echo/ 

call :PromptUser 1 "What is your username on Discord?" 
call :PromptUser 2 "What is ...?" 

rem Restore saved environment and exit batch processing. 
endlocal 
goto :EOF 

rem This small subroutine prompts the user for an input until something is 
rem entered at all and then appends the entered input to the report file. 

:PromptUser 
set "Input=" 
:PromptAgain 
set /P "Input=Question %~1: %~2 " 
rem Has the user entered anything at all? 
if not defined Input goto PromptAgain 
echo !Input!>>"%ReportFile%" 
goto :EOF 

Zum Verständnis die verwendeten Befehle und wie sie funktionieren, öffnen ein Eingabeaufforderungsfenster, führen dort die folgenden Befehle aus und lesen alle Hilfeseiten, die für jeden Befehl angezeigt werden, sehr sorgfältig durch.

• call /?
• del /?
• echo /?
• endlocal /?
• goto /?
• if /?
• rem /?
• set /?
• setlocal /?

Lesen Sie auch die Microsoft Artikel über Using Command Redirection Operators und Wikipedia-Artikel über Windows Environment Variables.