Aktualisieren Wert der Zielzelle in Excel VBA

Question

Ich versuche, den Wert der Zielzelle mit VBA-Makro zu aktualisieren, wenn es in bestimmten Bereich existiert. Ich möchte seinen Wert aktualisieren, indem ich einen String mit seinem Wert verkette. Wenn zum Beispiel 250 in die Zielzelle schreibt, möchte ich "XYZ-250" in die Zielzelle zurückschreiben. Unten ist der Code:

Dim oldCellAddress As String 
Dim oldCellValue As String 
Private Sub Worksheet_Change(ByVal Target As Range) 
oldCellValue = 0 
If Not Intersect(Target, Range("E10:E500")) Is Nothing Then 
oldCellValue = Target.Value 
Sheet1.Cells(Target.Row, Target.Column).Value = "AST-" & oldCellValue 
End If 
End Sub 

Interessanterweise, wenn ich den Wert einer Zelle innerhalb des Bereichs (E10 bis E500) ändern wird das messagebox unendlich Mal angezeigt und hält die Excel und ich habe es wieder neu zu starten.

Vielen Dank im Voraus

Answer 1

deaktivieren Ereignisse vor, eine Änderung zu machen, die das Change Ereignis ausgelöst wird:

Dim oldCellAddress As String 
Dim oldCellValue As String 
Private Sub Worksheet_Change(ByVal Target As Range) 
    oldCellValue = 0 
    If Not Intersect(Target, Range("E10:E500")) Is Nothing Then 
     Application.EnableEvents = False 
     oldCellValue = Target.Value 
     Target.Value = "AST-" & oldCellValue 
     Application.EnableEvents = True 
    End If 
End Sub 

Wenn Ereignisse nicht deaktiviert sind, Ihre Änderung wird Feuer auf die Zelle, die die Worksheet_Change Ereignis, das wird die Zelle ändern, die das Worksheet_Change Ereignis auslösen wird, das die Zelle ändern wird, die das Worksheet_Change Ereignis auslöst, das die Zelle ändern wird, die das Worksheet_Change Ereignis auslösen wird, das die Zelle ändern wird, die das feuern wird. ..

---

Angenommen, Sie nicht Ihre oldCellValue und oldCellAddress Modul-Scope-Variablen benötigen, aber nicht wollen, Änderungen an mehreren Zellen zu handhaben, diese stattdessen verwenden:

Private Sub Worksheet_Change(ByVal Target As Range) 
    If Not Intersect(Target, Range("E10:E500")) Is Nothing Then 
     Dim c As Range 
     Application.EnableEvents = False 
     For Each c In Intersect(Target, Range("E10:E500")).Cells 
      c.Value = "AST-" & c.Value 
     Next 
     Application.EnableEvents = True 
    End If 
End Sub