Die plattformübergreifende Lösung sollte die MacApi.AppKit und Windows.Winapi zusammen in bedingten Definitionen verwenden.
zuerst diesen Code auf Ihre uses-Klausel hinzufügen:
{$IFDEF MACOS}
MacApi.Appkit,Macapi.CoreFoundation, Macapi.Foundation,
{$ENDIF}
{$IFDEF MSWINDOWS}
Winapi.Messages, Winapi.Windows,
{$ENDIF}
Sie dann diesen Code in Ihrer Implementierung hinzu:
{$IFDEF MSWINDOWS}
function EnumFontsProc(var LogFont: TLogFont; var TextMetric: TTextMetric;
FontType: Integer; Data: Pointer): Integer; stdcall;
var
S: TStrings;
Temp: string;
begin
S := TStrings(Data);
Temp := LogFont.lfFaceName;
if (S.Count = 0) or (AnsiCompareText(S[S.Count-1], Temp) <> 0) then
S.Add(Temp);
Result := 1;
end;
{$ENDIF}
procedure CollectFonts(FontList: TStringList);
var
{$IFDEF MACOS}
fManager: NsFontManager;
list:NSArray;
lItem:NSString;
{$ENDIF}
{$IFDEF MSWINDOWS}
DC: HDC;
LFont: TLogFont;
{$ENDIF}
i: Integer;
begin
{$IFDEF MACOS}
fManager := TNsFontManager.Wrap(TNsFontManager.OCClass.sharedFontManager);
list := fManager.availableFontFamilies;
if (List <> nil) and (List.count > 0) then
begin
for i := 0 to List.Count-1 do
begin
lItem := TNSString.Wrap(List.objectAtIndex(i));
FontList.Add(String(lItem.UTF8String))
end;
end;
{$ENDIF}
{$IFDEF MSWINDOWS}
DC := GetDC(0);
FillChar(LFont, sizeof(LFont), 0);
LFont.lfCharset := DEFAULT_CHARSET;
EnumFontFamiliesEx(DC, LFont, @EnumFontsProc, Winapi.Windows.LPARAM(FontList), 0);
ReleaseDC(0, DC);
{$ENDIF}
end;
Jetzt können Sie CollectFonts Verfahren verwenden. Vergessen Sie nicht, eine non-nil TStringlist an die Prozedur zu übergeben. Eine typische Verwendung könnte so aussehen.
procedure TForm1.FormCreate(Sender: TObject);
var fList: TStringList;
i: Integer;
begin
fList := TStringList.Create;
CollectFonts(fList);
for i := 0 to fList.Count -1 do
begin
ListBox1.Items.Add(FList[i]);
end;
fList.Free;
end;
Vielen Dank! Ich werde es als korrekt akzeptieren, wenn ich die Chance bekomme, es zu testen, aber es sieht wie eine gute Antwort für mich aus :) – sergeantKK
Hallo, Sie können in meinem Blog nach einer funktionierenden Lösung suchen: http://delphiscience.wordpress.com/2012/11/20/getting-system-fonts-liste-in-firemonkey-the-new-tplatformextensions-class/ –
@ mehmed.ali Übrigens; In Ihrem Profil gibt es einen Platz, an dem Sie einen Link zur Startseite Ihres Blogs hinzufügen können (und sollten). –