Erstes Argument entweder Unterbefehl oder Flag mit Werten

Question

Ich schreibe ein Zsh-Vervollständigungsskript für die Swift-Tools (Compiler und Paket-Manager). Dieser Befehl kann mit oder ohne Angabe eines Unterbefehls verwendet werden. Zum Beispiel

# calls to the compiler 
# usage: swift [options] <inputs> 
1> swift my_file.swift 
2> swift -a 1 -b 2 my_file.swift 

# calls to build subcommand 
3> swift build 
4> swift build -c 1 

# calls to test subcommand 
5> swift test 
6> swift test -d 4 

Bis jetzt habe ich das folgende Abschluss-Skript. Es funktioniert meistens, aber für den nackten Anruf funktioniert die Autovervollständigung nicht ganz richtig. Es gibt die _compiler-Methode ein, aber es wird nicht korrekt nach swift -a automatisch vervollständigt. Es wird automatisch kompiliert, als hätte es -a vergessen. So sollte swift -a <TAB><TAB> das Menü zum Auswählen von 1-2-3 anzeigen; Stattdessen zeigt es eine Dateiliste. Für swift -a -a <TAB><TAB> zeigt es die korrekten Vervollständigungen, aber die Wiederholung -a ist nicht gültig.

Es hat wahrscheinlich etwas mit dem Zustand zu tun, der geändert wurde, während es für diesen speziellen Anwendungsfall nicht haben sollte. Für die Unterbefehle (build & test) sollte der Status jedoch so geändert werden, dass die entsprechenden Vervollständigungen ordnungsgemäß funktionieren.

Ich habe die Dokumentation durchgelaufen, aber es ist sehr kryptisch. Ich habe verschiedene andere Abschluss-Skripte überprüft, konnte aber den fehlenden Link nicht herausfinden. Also, wie kann ich eine Vervollständigung für einen Befehl angeben, der optionale Unterbefehle hat, die getrennte Merkergruppen haben (und auch Subunterbefehle selbst haben)?

#compdef swift 
local context state state_descr line 
typeset -A opt_args 

_swift() { 
    _arguments -C \ 
     ': :->command' \ 
     '*:: :->arg' 

    case $state in 
     (command) 
      local tools 
      tools=(
       'build:description for build' 
       'test:description for test' 
      ) 
      _alternative \ 
       'tools:common:{_describe "tool" tools }' \ 
       'compiler: :_compiler' 
      ;; 
     (arg) 
      case ${words[1]} in 
       (build) 
        _build 
        ;; 
       (test) 
        _test 
        ;; 
       (*) 
        _compiler 
        ;; 
      esac 
      ;; 
    esac 
} 

_compiler() { 
    _arguments -C \ 
     '(-a)-a[description for a]: :(1 2 3)' \ 
     '(-b)-b[description for b]: :(4 5 6)' \ 
     '*: :_files' 
} 

_build() { 
    _arguments -C \ 
     '-c[description for c]: :(1 2 3)'  
} 

_test() { 
    _arguments -C \ 
     '-d[description for d]: :(4 5 6)'  
} 

Answer 1

Sie könnte es tun mit _regex_words und _regex_arguments:

local -a abopts buildopts testopts cmds aargs bargs cargs dargs 
local matchany=/$'[^\0]##\0'/ 
aargs=(/$'(1|2|3)\0'/ ':number:number:(1 2 3)') 
bargs=(/$'(4|5|6)\0'/ ':number:number:(4 5 6)') 
cargs=(/$'(1|2|3)\0'/ ':number:number:(1 2 3)') 
dargs=(/$'(4|5|6)\0'/ ':number:number:(4 5 6)') 
_regex_words opt 'options' '-a:description for a:$aargs' '-b:description for b:$bargs' 
abopts=("${reply[@]}") 
_regex_words opt 'options' '-c:description for c:$cargs' 
buildopts=("${reply[@]}") 
_regex_words opt 'options' '-d:description for d:$dargs' 
testopts=("${reply[@]}") 
_regex_words cmd 'commands' 'build:build command:$buildopts' 'test:test command:$testopts' 
cmds=("${reply[@]}") 

_regex_arguments _swift "$matchany" \("${cmds[@]}" \| "${abopts[@]}" "$matchany" ":file:file:{_files}" \) 
_swift "$@" 

Sie darüber lesen, wie diese Funktionen hier verwenden: http://zsh.sourceforge.net/Doc/Release/Completion-System.html#Completion-Functions oder hier: https://github.com/vapniks/zsh-completions/blob/master/zsh-completions-howto.org