AWK-Syntaxfehler bei Verwendung der IF-Anweisung

Question

Ich bin sehr neu in AWK, obwohl ich zuvor die Eingabeaufforderung/Terminal verwendet habe.

Ich habe dieses Skript unten, wo ich Teilmengen von Daten basierend auf Country Code und State Code erstellen. Aber ich bekomme einen Syntaxfehler.

BEGIN{ 
    FS = "\t" 
    OFS = "\t" 
    } 

# Subset data from the states you need for all years 
if ($5 == "IN-GA" || $5 == "IN-DD" || $5 == "IN-DN" || $5 == "IN-KA" || $5 == "IN-KL" || $5 == "IN-MH" || $5 == "IN-TN" || $5 == "IN-GJ"){ 
     if (substr($17, 1, 4) == "2000"){ 
      print $5, $12, $13, $14, $15, $16, $17, $22, $23, $24, $25, $26, $28 > "Y2000_India_sampling_output.txt" 
     } 
    } 

auf Cygwin verweise ich auf das Skript und ich führen Sie die folgenden Zeilen Code und sehen Sie die Syntaxfehler sofort:

$ gawk -f sampling_India.awk sampling_relFeb-2017.txt 
gawk: sampling_India.awk:20: gawk if ($5 == "IN-GA" || $5 == "IN-DD" || $5 == "IN-DN" || $5 == "IN-KA" || $5 == "IN-KL" || $5 == "IN-MH" || $5 == "IN-TN" || $5 == "IN-GJ"){ 
gawk: sampling_India.awk:20:  ^syntax error 

Irgendwelche Gedanken?

Answer 1

Ihr if Zustand ist nicht in {...} Block eingeschlossen.

haben es wie folgt aus:

BEGIN { 
    FS = OFS = "\t" 
} 
# Subset data from the states you need for all years 
$5 ~ /^IN-(GA|DD|DN|KA|KL|MH|TN|GJ)$/ && substr($17, 1, 4) == "2000" { 
    print $5, $12, $13, $14, $15, $16, $17, $22, $23, $24, $25, $26, $28 > "Y2000_India_sampling_output.txt" 
} 

Beachten Sie, wie regex Sie mehrere == Bedingungen in einer einzigen Bedingung kombinieren.