Das richtige ReadP-Analyseergebnis auswählen

Question

Ich versuche, eine RFC5322-E-Mail-Adresse zu analysieren. Mein Parser funktioniert in dem Sinne, dass unter den Ergebnissen einer von ihnen korrekt ist. Wie kann ich das "richtige" Ergebnis auswählen?

Angesichts der Zeichenfolge Foo Bar <foo@bar.com>, sollte mein Parser einen Wert von Address (Just "Foo Bar") "foo@bar.com" produzieren.

Alternativ könnte der Parser bei der Zeichenfolge den Wert Address Nothing "foo@bar.com" ausgeben.

Der Wert mit dem eingeschlossenen Namen wird bevorzugt.

Mein Parser sieht wie folgt aus:

import   Control.Applicative 
import   Data.Char 
import qualified Data.Text      as T 
import   Text.ParserCombinators.ReadP 

onlyEmail :: ReadP Address 
onlyEmail = do 
    skipSpaces 
    email <- many1 $ satisfy isAscii 
    skipSpaces 
    return $ Address Nothing (T.pack email) 

withName :: ReadP Address 
withName = do 
    skipSpaces 
    name <- many1 (satisfy isAscii) 
    skipSpaces 
    email <- between (char '<') (char '>') (many1 $ satisfy isAscii) 
    skipSpaces 
    return $ Address (Just $ T.pack name) (T.pack email) 

rfc5322 :: ReadP Address 
rfc5322 = withName <|> onlyEmail 

Wenn ich den Parser mit readP_to_S rfc5322 "Foo Bar <foo@bar.com>" laufen, es produziert die folgenden Ergebnisse:

[ (Address {addressName = Nothing, addressEmail = "F"},"oo Bar <foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Fo"},"o Bar <foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo"},"Bar <foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo "},"Bar <foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo B"},"ar <foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Ba"},"r <foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar"},"<foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar "},"<foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <"},"foo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <f"},"oo@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <fo"},"o@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo"},"@bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@"},"bar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@b"},"ar.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@ba"},"r.com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@bar"},".com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@bar."},"com>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@bar.c"},"om>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@bar.co"},"m>") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@bar.com"},">") 
, (Address {addressName = Just "Foo Bar", addressEmail = "foo@bar.com"},"") 
, (Address {addressName = Just "Foo Bar ", addressEmail = "foo@bar.com"},"") 
, (Address {addressName = Nothing, addressEmail = "Foo Bar <foo@bar.com>"},"") 
] 

In diesem Fall ist das Ergebnis, das ich möchte tatsächlich erscheint dritt- zuletzt in der Liste. Wie drücke ich diese Präferenz aus?

Answer 1

Sie sollten nicht bevorzugen. Ihr Problem besteht darin, dass Ihre partiellen Parser den größeren String-Satz akzeptieren als wirklich nötig.

Zum Beispiel meine Lösung:

import   Control.Bool 
import   Control.Applicative 
import   Data.Char 
import qualified Data.Text      as T 
import   Data.Text (Text) 
import   Text.ParserCombinators.ReadP 

email :: ReadP Text 
email = do 
    l <- part 
    a <- char '@' 
    d <- part 
    return . T.pack $ l ++ a:d 
    where 
    part = munch1 (isAscii <&&> (/='@') <&&> (/='<') <&&> (/='>')) 

name :: ReadP Text 
name = T.pack <$> chainr1 part sep 
    where 
    part = munch1 (isAlpha <||> isDigit <||> (=='\'')) 
    sep = (\xs ys -> xs ++ ' ':ys) <$ munch1 (==' ') 

onlyEmail :: ReadP Address 
onlyEmail = Address Nothing <$> email 

withName :: ReadP Address 
withName = do 
    n <- name 
    skipSpaces 
    e <- between (char '<') (char '>') email 
    return $ Address (Just n) e 

address :: ReadP Address 
address = skipSpaces *> (withName <|> onlyEmail) 

main = print $ readP_to_S address "Foo Bar <foo@bar.com>" 

gedruckt:

[(Address (Just "Foo Bar") "foo@bar.com","")]