Wie zeichne 3 Spalten in GNUplot?

Question

Ich habe Dateien wie folgt aussehen:

Number Data1 Data2 
1 9.10 4.022 
2 15.27 3.996 
3 21.92 4.004 
4 21.19 4.026 
5 20.67 4.022 
6 20.99 4.000 
7 19.80 4.004 
8 20.01 3.931 
9 20.18 4.004 
10 19.78 4.007 

I Nummer in der X-Achsen, Data1 in Lefty und Data2 in righty plotten möchten, aber ich kann nicht herausfinden, wie es zu tun.

Dank

Answer 1

Nur eine kurze kommentierte Probe, Ihre Daten in einer Datei gespeichert so.dat mit:

# Set ticks for 2nd y axis 
set y2tics 
# We don't want to see the left ticks on the right axis 
set ytics nomirror 

# Set ranges so that the data points are not on the axis 
set xrange [0:11] 
set yrange [8:23] 
set y2range[3.95:4.05] 

# use first line of the file for labels 
set key autotitle columnhead 
# display key in least busy area 
set key bottom right 

# Title and axis labels 
set title "Nice Try" 
set xlabel "Number" 
set ylabel "Data1" 
set y2label "Data2" 

plot "so.dat" using 1:2 axes x1y1 with points pointsize 2,\ 
    "" u 1:3 axes x1y2 w p ps 2 pointtype 6 

Man kann viel mehr Dekoration etc. tun, aber ich denke, das ist die Essenz dessen, was Sie wollen. Das erzeugte Diagramm: