vim - mit mehr als einem Marker Falten

Question

ich eine Debug-Datei, die wie folgt aussieht:

==>func1: 
..... 
.. 
==>func2: 
...... 
... 
<==func2 
.. 
<==func1 
==>func3: 
...... 
... 
<==func3 

Grundsätzlich wäre Ich mag Lage sein, jede der Funktionen zu falten, um schließlich so etwas wie dies zu sehen:

+-- x lines: ==> func1: 
+-- x lines: ==> func3: 

aber noch in der Lage sein func1 um zu erweitern und func2 gefaltet:

==>func1: 
..... 
.. 
+-- x lines: ==> func2: 
.. 
<==func1 

gibt es eine Möglichkeit, dies zu tun? Vielen Dank.

Answer 1

Die unerreichte Marker benötigen zusätzliche Griff, hier ist eine ausdr Lösung (siehe :h fold-expr):

setlocal foldmethod=expr 
setlocal foldexpr=GetFoldlevel(v:lnum) 

function GetFoldlevel(lnum) 
    let line = getline(a:lnum) 

    let ret = '=' 
    if line[0:2] == '==>' 
     let name = matchstr(line, '^==>\zs\w*') 
     let has_match = HasMarkerMatch(a:lnum, name) 
     if has_match 
      let ret = 'a1' 
     endif 
    elseif line[0:2] == '<==' 
     let ret ='s1' 
    endif 

    return ret 
endfunction 

function HasMarkerMatch(lnum, name) 
    let endline = line('$') 
    let current = a:lnum + 1 

    let has_match = 0 
    while current <= endline 
     let line = getline(current) 

     if line =~ '^<=='.a:name 
      let has_match = 1 
      break 
     endif 

     let current += 1 
    endwhile 

    return has_match 
endfunction