Wie fasst man mehrere Zeichenketten mit Move zusammen?

Question

Wie kann ich ein Array von Strings mit Move concat. Ich habe das versucht, aber ich kann mir einfach nicht vorstellen, wie der Move-Vorgang richtig funktioniert.

program Project2; 

{$POINTERMATH ON} 

procedure Concat(var S: String; const A: Array of String); 
var 
    I, J: Integer; 
    Len: Integer; 
begin 
    Len := 0; 
    for I := 0 to High(A) do 
    Len := Len + Length(A[I]); 

    SetLength(S, Length(S) + Len); 

    for I := 0 to High(A) do 
    Move(PWideChar(A[I])[0], S[High(S)], Length(A[I]) * SizeOf(WideChar)); 
end; 

var 
    S: String; 
begin 
    S := 'test'; 
    Concat(S, ['test', 'test2', 'test3']); 
end. 

Answer 1

würde ich diese Funktion wie so schreiben:

procedure Concat(var Dest: string; const Source: array of string); 
var 
    i: Integer; 
    OriginalDestLen: Integer; 
    SourceLen: Integer; 
    TotalSourceLen: Integer; 
    DestPtr: PChar; 
begin 
    TotalSourceLen := 0; 
    OriginalDestLen := Length(Dest); 
    for i := low(Source) to high(Source) do begin 
    inc(TotalSourceLen, Length(Source[i])); 
    end; 
    SetLength(Dest, OriginalDestLen + TotalSourceLen); 

    DestPtr := PChar(Pointer(Dest)) + OriginalDestLen; 
    for i := low(Source) to high(Source) do begin 
    SourceLen := Length(Source[i]); 
    Move(Pointer(Source[i])^, DestPtr^, SourceLen*SizeOf(Char)); 
    inc(DestPtr, SourceLen); 
    end; 
end; 

Es ist ziemlich selbsterklärend. Die Komplikationen werden durch leere Strings verursacht. Jeder Versuch, Zeichen einer leeren Zeichenfolge zu indizieren, führt zu Ausnahmen, wenn die Bereichsüberprüfung aktiviert ist.

Um diese Komplikation zu behandeln, können Sie if Tests für den Fall hinzufügen, in dem eine der Zeichenfolgen, die an dem -Aufruf beteiligt sind, leer ist. Ich bevorzuge einen anderen Ansatz. Ich würde die String-Variable lieber als Zeiger ausgeben. Dies umgeht die Bereichsüberprüfung, erlaubt aber auch das Auslassen der if-Anweisung.

Move(Pointer(Source[i])^, DestPtr^, SourceLen*SizeOf(Char)); 

Man könnte sich fragen, was passiert, wenn Source[i] leer ist. In diesem Fall ist Pointer(Source[i])nil und Sie könnten eine Zugriffsverletzung erwarten. In der Tat gibt es keinen Fehler, da die Länge der Verschiebung, wie durch das dritte Argument spezifiziert, Null ist, und der Zeiger nil niemals tatsächlich de-referenziert wird.

Die andere Linie Bemerkenswert ist hier:

DestPtr := PChar(Pointer(Dest)) + OriginalDestLen; 

Wir verwenden PChar(Pointer(Dest)) statt PChar(Dest). Letzterer ruft Code auf, um zu prüfen, ob Dest leer ist oder nicht, und wenn dies der Fall ist, liefert er einen Zeiger auf einen einzelnen Null-Terminator. Wir möchten vermeiden, dass dieser Code ausgeführt wird, und die Adresse erhalten, die in Dest direkt gehalten wird, selbst wenn es nil ist.

Answer 2

In der zweiten Schleife Sie vergessen, dass S bereits die richtige Größe hat mit allen Elementen zu erhalten gefüllt, so dass Sie eine andere Variable zu verwenden, haben die Ziel Parameter von Move

procedure Concat(var S: String; const A: Array of String); 
var 
    I, Len, Sum: Integer; 
begin 
    Len := 0; 
    for I := 0 to High(A) do 
    Inc(Len, Length(A[I])); 
    Sum := Length(S); 
    SetLength(S, Sum + Len); 
    for I := 0 to High(A) do 
    begin 
    if Length(A[I]) > 0 then 
     Move(A[I][1], S[Sum+1], Length(A[I]) * SizeOf(Char)); 
    Inc(Sum, Length(A[I])); 
    end; 
end; 

wissen Casting der Quelle Parameter zu PWideChar ist völlig überflüssig, da die Funktion verwenden eine Art von alten generischen Syntax tha t erlaubt, alles zu übergeben, was Sie wollen (const Parameter ohne Typ).