Excel - Select Case mit mehreren Kriterien

Question

Der folgende Code ist eine Art Auszug aus meinem vollständigen Sub, nur weil es hier leichter zu lesen ist. Ich muss einigen Fällen weitere Kriterien hinzufügen, und ich bin mir nicht sicher, wie ich das umsetzen soll.

Um zusammenzufassen, was das in einer Zeile macht, wenn Spalte K ein Wort hat, das mit B, M oder D beginnt, führt es eine Reihe von Fällen aus. Wenn Spalte K ein Wort hat, das mit einem A beginnt, wird ein anderer Satz von Fällen ausgeführt. Auch das funktioniert. Aber in einigen dieser Fälle brauche ich mehr Kriterien, anstatt nur Spalte O zu betrachten.

Zum Beispiel muss im ersten Fall nach "University of Illinois" und "UofI" gesucht werden, aber es muss auch Spalte P für die Werte von "Urbana" und "Chicago" überprüfen. Wie kann ich das machen?

Sub Test4() 
    Dim LastRow As Long 
    Dim i As Long 
    LastRow = Range("O" & Rows.Count).End(xlUp).Row 
    For i = 84 To LastRow 
     If Range("K" & i) Like "B*" Or Range("K" & i) Like "M*" Or Range("K" & i) Like "D*" Then 
      Select Case Range("O" & i) 
       Case "University of Illinois", "UofI" 
        Range("N" & i) = "1234" 
      End Select 
     End If 
     If Range("K" & i) Like "A*" Then 
      Select Case Range("O" & i) 
       Case "New York University", "NYU" 
        Range("N" & i) = "5075" 
      End Select 
     End If 
    Next i 
End Sub 

Answer 1

Select Case Range("O" & i) 
    Case "University of Illinois", "UofI" 
     Select Case Range("P" & i") 
      Case "Urbana", "Chicago" 
       Range("N" & i) = "1234" 
     End Select 
End Select 

genügt das? Haben Sie nicht getestet, damit wir Sie zu einer Lösung

Answer 2

Select Case Anweisung normalerweise nicht mit dem Operator Like arbeiten können. Es gibt jedoch einen Workaround.

Um die Select Case mit der Like zu arbeiten, fügen wir einen True Ausdruck hinzu.

-Code

Sub Test4() 

    Dim LastRow As Long 
    Dim i As Long 

    LastRow = Range("O" & Rows.Count).End(xlUp).Row 
    For i = 84 To LastRow 

     Dim wordStr 
     wordStr = Range("K" & i) 

     ' adding True to enter the below Case with Like 
     Select Case True 
      Case wordStr Like "B*", wordStr Like "M*", wordStr Like "D*" 
       Select Case Range("O" & i) 
        Case "University of Illinois", "UofI" 
         Range("N" & i) = "1234" 

       End Select 

      Case wordStr Like "A*" 
       Select Case Range("O" & i) 
        Case "New York University", "NYU" 
         Range("N" & i) = "5075" 

       End Select 

     End Select 
    Next i 

End Sub 

Answer 3

da Sie brauchen "Wort, das mit beginnt" fangen Sie diese

Sub Test4() 
    Dim LastRow As Long, i As Long 

    LastRow = Range("O" & Rows.count).End(xlUp).row 
    For i = 84 To LastRow 
     Select Case Left(Range("K" & i).Value, 1) 
      Case "B", "M", "D" 
       Select Case Range("O" & i).Value 
        Case "University of Illinois", "UofI" 
         Range("N" & i) = "1234" 
       End Select 
      Case "A" 
       Select Case Range("O" & i).Value 
        Case "New York University", "NYU" 
         Range("N" & i) = "5075" 
       End Select 
     End Select 
    Next i 
End Sub