Installation sphinx + re2 auf Arch Linux

Question

Ich muss sphinx mit regexp_filter Option installieren. Ich habe re2 Paket mit Pacman installiert. In der Dokumentation sehe ich, dass ich das sphinx Paket mit --with-re2 Option kompilieren kann. Aber wenn ich das tue, bekomme ich Fehler.

checking whether to compile with RE2 library support... configure: error: missing re2 sources 

Auch habe ich versucht make Optionen wie here einzustellen.

--with-re2-libs=/usr/lib/libre2.so --with-re2-includes=/usr/include/re2/ 

aber ich habe einen anderen Fehler bekam

checking whether to compile with RE2 library support... configure: error: missing re2 headers 

Hier meine Ausgabe von ls /usr/include/re2

ls /usr/include/re2/ 
    filtered_re2.h 
    re2.h 
    set.h 
    stringpiece.h 
    variadic_function.h 

Lassen Sie sich diese jemand installieren? Danke für die Hilfe!

Answer 1

Ich habe die Lösung meines Problems gefunden.

Ich ersetzte

--with-re2-libs=/usr/lib/libre2.so --with-re2-includes=/usr/include/re2/ 

mit diesem

--with-re2-libs=/usr/lib/ --with-re2-includes=/usr/include/re2/ 

Hier die vollständige PKGBUILD Datei:

# Maintainer: Isaac Aronson <i at linux dotcom> 
# Contributor: Dan Serban 
# Contributor: Jim Casteel 
# Contributor: dryes <joswiseman@gmail> 
# Contributor: Vishnevsky Roman <aka dot x0x01 at gmail dot com> 
# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com> 
# Contributor: Aldo Culquicondor <alculquicondor@gmail.com> 
# Contributor: Florijan Hamzic <florijanh@gmail.com> 
pkgname='sphinx' 
pkgver=2.2.10 
pkgrel=2 
pkgdesc='Free open-source SQL full-text search engine.' 
arch=('i686' 'x86_64') 
url='http://www.sphinxsearch.com/' 
license=('GPL') 
depends=('unixodbc' 'expat' 'libmysqlclient' 'postgresql-libs' 're2') 
optdepends=('postgresql') 
backup=('etc/conf.d/sphinx') 
install='sphinx.install' 
source=("http://sphinxsearch.com/files/${pkgname}-${pkgver}-release.tar.gz" 
    'sphinx.conf.d' 
    'sphinx.rc.d' 
    'sphinx.service' 
    'sphinx.tmpfiles.conf') 

build() { 
    sed -i '15199,15199 s/x00/x21/' "${srcdir}/${pkgname}-${pkgver}-release/src/searchd.cpp" 

    cd "${srcdir}/${pkgname}-${pkgver}-release" 
    ./configure --prefix=/usr --exec-prefix=/usr --localstatedir=/var/lib/sphinx \ 
    --sysconfdir=/etc/sphinx --with-pgsql --enable-id64 --with-re2 --with-re2-include=/usr/include/re2 --with-re2-libs=/usr/lib/libre2.so 

    make 
} 

package() { 
    cd "${srcdir}/${pkgname}-${pkgver}-release" 

    make DESTDIR="${pkgdir}" install 

    for _f in "${pkgdir}/usr/bin/"*; do 
    ln -s "/usr/bin/${_f##*/}" "${pkgdir}/usr/bin/sphinx-${_f##*/}" 
    done 

    install -Dm755 "${srcdir}/sphinx.rc.d" "${pkgdir}/etc/rc.d/sphinx" 
    install -Dm644 "${srcdir}/sphinx.conf.d" "${pkgdir}/etc/conf.d/sphinx" 
    install -Dm644 "${srcdir}/sphinx.service" "${pkgdir}/usr/lib/systemd/system/sphinx.service" 
    install -d "${pkgdir}/usr/share/sphinx/lib" 
    install -Dm644 api/sphinxapi.php "${pkgdir}/usr/share/sphinx/lib/sphinxapi.php" 
    install -Dm644 api/sphinxapi.py "${pkgdir}/usr/share/sphinx/lib/sphinxapi.py" 
    install -Dm644 "${srcdir}/sphinx.tmpfiles.conf" "${pkgdir}/usr/lib/tmpfiles.d/sphinx.conf" 
} 
md5sums=('dda52b24d8348fc09e26d8a649a231d2' 
     '48e3e1857919d26d5104a48caffb531b' 
     'faaa8310af97ff1dbdaf08612e442020' 
     'fe06a8aff0520a6f75596ee43d2e5935' 
     '22ec4cd0471a1d52702d57d78614b8d8')