Wie emphiere ich Hyperkey in Windows 10 mit autohotkey

Question

Ich migriere meine Mac-Workflow zu Windows. Eine Sache, ohne die ich nicht leben könnte, ist der Hyperkey, der eine Kombination aus Ctrl + Option + Shift + Cmd ist. Ich benutze Karabiner App, Capslock zu diesem Schlüssel neu zuordnen. Ich habe gehört, dass Autohotkey ist ein Karabiner Alternative für Windows. Könnt ihr mir bitte helfen, diese Funktion in Windows zu emulieren?

Mein ideales Ergebnis ist:

• deaktivieren Capslock vollständig, weil ich diese selten
• Toggle verwenden Capslock wird ESC Schlüssel
• Capslock wird durchführen Halten Sie führen Ctrl + Alt + Shift + Windows. Zum Beispiel Capslock + C wird Ctrl+Alt+Shift+Windows+C sein

Vielen Dank im Voraus!

Das folgende ist mein Versuch mit ahk Skript, aber es hat nicht funktioniert :(

;----------------------------------------- 
; hyper key for windows 
;========================================= 

; -------------------------------------------------------------- 
; notes 
; -------------------------------------------------------------- 
; ! = alt 
;^= ctrl 
; + = shift 
; # = lwin|rwin 
; 
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases. 
#UseHook 
#InstallKeybdHook 
#SingleInstance force 

SendMode Input 

;; deactivate capslock completely 
SetCapslockState, AlwaysOff 

;; remap capslock to hyper 
Capslock:: 
SendInput {Blind}{Ctrl Down}{Alt Down}{Shift Down}{LWin Down} 
return 

Capslock up:: 
SendInput {Blind}{Ctrl Up}{Alt Up}{Shift Up}{LWin Up} 
return 

;; vim navigation with hyper 
^!+#h:: SendInput {Blind}{Left} 
^!+#h up:: SendInput {Blind}{Left Up} 
^!+#l:: SendInput {Blind}{Right} 
^!+#k:: SendInput {Blind}{Up} 
^!+#j:: SendInput {Blind}{Down} 

;; popular hotkeys with hyper 
^!+#c::^c 
^!+#v::^v 

Answer 1

Vielen Dank für jeden, der versucht, mir zu helfen, dachte ich, meine eigenen, die prob heraus und teilen möchte es für den Fall, in diesem prob jemand kommt

#NoEnv ; recommended for performance and compatibility with future autohotkey releases. 
#UseHook 
#InstallKeybdHook 
#SingleInstance force 

SendMode Input 

;; deactivate capslock completely 
SetCapslockState, AlwaysOff 

;; remap capslock to hyper 
;; if capslock is toggled, remap it to esc 

;; note: must use tidle prefix to fire hotkey once it is pressed 
;; not until the hotkey is released 
~Capslock:: 
    ;; must use downtemp to emulate hyper key, you cannot use down in this case 
    ;; according to https://autohotkey.com/docs/commands/Send.htm, downtemp is as same as down except for ctrl/alt/shift/win keys 
    ;; in those cases, downtemp tells subsequent sends that the key is not permanently down, and may be 
    ;; released whenever a keystroke calls for it. 
    ;; for example, Send {Ctrl Downtemp} followed later by Send {Left} would produce a normal {Left} 
    ;; keystroke, not a Ctrl{Left} keystroke 
    Send {Ctrl DownTemp}{Shift DownTemp}{Alt DownTemp}{LWin DownTemp} 
    KeyWait, Capslock 
    Send {Ctrl Up}{Shift Up}{Alt Up}{LWin Up} 
    if (A_PriorKey = "Capslock") { 
     Send {Esc} 
    } 
return 

;; vim navigation with hyper 
~Capslock & h:: Send {Left} 
~Capslock & l:: Send {Right} 
~Capslock & k:: Send {Up} 
~Capslock & j:: Send {Down} 

;; popular hotkeys with hyper 
~Capslock & c:: Send ^{c} 
~Capslock & v:: Send ^{v}