Excel-Dateiname, Blattname und Seiten

Question

Wie kann ich Text FILE NAME, PAGE NAME, PAGE OF PAGES in einen automatischen Code ändern, Wenn ich &F für den Dateinamen verwende, bekomme ich Routing und alles vermasselt.

Es ist in Excel:

Sub Podnozje() 
' 
' Podnozje Makro 
' 
    Application.PrintCommunication = False 
    With ActiveSheet.PageSetup 
     .PrintTitleRows = "" 
     .PrintTitleColumns = "" 
    End With 
    Application.PrintCommunication = True 
    ActiveSheet.PageSetup.PrintArea = "" 
    Application.PrintCommunication = False 
    With ActiveSheet.PageSetup 
     .LeftHeader = "" 
     .CenterHeader = "" 
     .RightHeader = "" 
     .LeftFooter = "&""Arial,Standard""&10Ersteller: CUTC HR" 
     .CenterFooter = "&""Arial,Standard""&10FILE NAME" & Chr(10) & "PAGE NAME" & Chr(10) & "PAGE OF PAGES" 
     .RightFooter = "&""Arial,Standard""&10Druckdatum: &Date" 
    End With 
    Application.PrintCommunication = True 
End Sub 

Answer 1

In einer frischen Arbeitsmappe den folgenden Code

Option Explicit 

Public Sub GenerateFooters() 
    With ActiveSheet.PageSetup 
     .LeftFooter = "" 
     .CenterFooter = "" 
     .RightFooter = "" 'sometimes I had issues without clearing the footer first 

     .LeftFooter = "&""Arial,Standard""&10 Ersteller: CUTC HR" 
     .CenterFooter = "&""Arial,Standard""&10 &F" & Chr(10) & "&A" & Chr(10) & "Seite &P von &N" 
     .RightFooter = "&""Arial,Standard""&10 Druckdatum: &D" 
    End With 
End Sub 

Ergebnisse in

---

Diese ar e die gültigen Codes:

• &P - die aktuelle Seitennummer.
• &N - die Gesamtzahl der Seiten.
• &B - verwenden Sie eine Fettschrift *.
• &I - verwenden Sie eine kursive Schriftart *.
• &U - Verwenden Sie eine Unterstreichungsschrift *.
• && - das Zeichen '&'.
• &D - das aktuelle Datum.
• &T - die aktuelle Zeit.
• &F - Arbeitsmappename.
• &A - Arbeitsblattname.
• &"FontName" - Verwenden Sie den angegebenen Schriftnamen.
• &N - verwenden Sie die angegebene Schriftgröße.