XSLT-Gruppe mit 2 verschiedenen Elementen

Question

Ich bin neu bei xslt. Ich versuche mit 2 verschiedenen Elementen zu gruppieren. Zuerst nach Arbeiter, dann nach Zahlencode. Bitte beachten Sie, dass die Beträge aufgrund der Gruppe nach Paycode summieren. Unten ist ein Vorher-Beispiel xsl, dann ein Beispiel nach xsl, das ich als Ausgabe möchte.

Vorher:

<?xml version='1.0' encoding='utf-8'?> 
<File xmlns:is="java:com.workday.esb.intsys.xpath.ParsedIntegrationSystemFunctions" 
    xmlns:tv="java:com.workday.esb.intsys.TypedValue"> 
    <Worker> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>5572.800000</Amount> 
     </Detail> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>FICA</PayCode> 
      <Amount>40.000000</Amount> 
     </Detail> 
    </Worker> 
    <Worker> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>13545.000000</Amount> 
     </Detail> 
    </Worker> 
    <Worker> 
     <Detail> 
      <EmployeeID>00</EmployeeID> 
      <FirstName>RUSSELL</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>84811.050000</Amount> 
     </Detail> 
    </Worker> 
</File> 

Was ich als Ausgabe haben möchte, zuerst von Worker Gruppierung, dann die Gruppe von Pay-Code. wegen der Gruppierung Beträge Summe:

<?xml version='1.0' encoding='utf-8'?> 
<File xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:tv="java:com.workday.esb.intsys.TypedValue"> 
    <Worker> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>19117.800000</Amount> 
     </Detail> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>FICA</PayCode> 
      <Amount>40.000000</Amount> 
     </Detail> 
    </Worker> 
    <Worker> 
     <Detail> 
      <EmployeeID>00</EmployeeID> 
      <FirstName>RUSSELL</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>84811.050000</Amount> 
     </Detail> 
    </Worker> 
</File> 

Unten ist mein XSL das nicht funktioniert:

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" exclude-result-prefixes="xsl wd xsd this env" 
    xmlns:wd="urn:com.workday/bsvc" 
    xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:env="http://schemas.xmlsoap.org/soap/envelope/" 
    xmlns:this="urn:this-stylesheet"> 

    <xsl:output indent="yes" method="xml"/> 
    <xsl:template match="/">  
     <File> 
      <Worker> 
       <xsl:for-each-group select="File" group-by="Worker"> 
        <Detail>    
         <EmployeeID><xsl:value-of select="Worker/current-group()/EmployeeID"></xsl:value-of></EmployeeID> 
         <FirstName><xsl:value-of select="//current-group()//FirstName"></xsl:value-of></FirstName> 
         <PayCode><xsl:value-of select="PayCode"></xsl:value-of></PayCode> 
         <Amount><xsl:value-of select="format-number(sum(current-group()/number(translate(Amount,',',''))),'######.00')"></xsl:value-of></Amount> 
        </Detail> 
       </xsl:for-each-group> 
      </Worker> 
     </File> 
    </xsl:template> 
</xsl:stylesheet> 

Kann jemand bitte SL setzen, die oben auf den gewünschten Ausgang verwandeln?
Ich arbeite seit Stunden daran und winke mit der weißen Flagge lol.

Vielen Dank!

Answer 1

Wenn Sie eine Gruppe für jeden EmployeeID haben wollen, auch innerhalb jeder Gruppe eine Untergruppe für jeden PayCode, dann müssen Sie natürlich auf Nest zweixsl:for-each-group Anweisungen. Und die Knoten, die Sie gruppieren müssen, sind die Detail Elemente, nicht die Wurzel File Element, von denen nur eins sein wird.

XSLT 2,0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/File">  
    <xsl:copy> 
     <xsl:for-each-group select="Worker/Detail" group-by="EmployeeID"> 
      <Worker> 
       <xsl:for-each-group select="current-group()" group-by="PayCode"> 
        <Detail>    
         <xsl:copy-of select="EmployeeID | FirstName | PayCode"/> 
         <Amount> 
          <xsl:value-of select="format-number(sum(current-group()/Amount),'#.000000')"/> 
         </Amount> 
        </Detail> 
       </xsl:for-each-group> 
      </Worker> 
     </xsl:for-each-group> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>